[Bio] / Sprout / Sprout.pm Repository:
ViewVC logotype

View of /Sprout/Sprout.pm

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.86 - (download) (as text) (annotate)
Sun Sep 24 17:14:16 2006 UTC (12 years, 11 months ago) by parrello
Branch: MAIN
Changes since 1.85: +95 -4 lines
Moved NMPDR group into the Genome record. This insures that all of the information required to generate a popup menu of genomes is available without access to secondary tables.

package Sprout;

    require Exporter;
    use ERDB;
    @ISA = qw(Exporter ERDB);
    use Data::Dumper;
    use strict;
    use Carp;
    use DBKernel;
    use XML::Simple;
    use DBQuery;
    use DBObject;
    use Tracer;
    use FIGRules;
    use FidCheck;
    use Stats;
    use POSIX qw(strftime);
    use BasicLocation;

=head1 Sprout Database Manipulation Object

=head2 Introduction

This object enables the user to load and query the Sprout genome database using a few simple methods.
To construct the object, specify the name of the database. By default, the database is assumed to be a
MySQL database accessed via the user ID I<root> with no password and the database definition will
be in a file called F<SproutDBD.xml>. All of these defaults can be overridden
on the constructor. For example, the following invocation specifies a PostgreSQL database named I<GenDB>
whose definition and data files are in a co-directory named F<Data>.

C<< my $sprout = Sprout->new('GenDB', { dbType => 'pg', dataDir => '../Data', xmlFileName => '../Data/SproutDBD.xml' }); >>

Once you have a sprout object, you may use it to re-create the database, load the tables from
tab-delimited flat files and perform queries. Several special methods are provided for common
query tasks. For example, L</genomes> lists the IDs of all the genomes in the database and
L</dna_seq> returns the DNA sequence for a specified genome location.

The Sprout object is a subclass of the ERDB object and inherits all its properties and methods.

=cut

#: Constructor SFXlate->new_sprout_only();

=head2 Public Methods

=head3 new

C<< my $sprout = Sprout->new($dbName, \%options); >>

This is the constructor for a sprout object. It connects to the database and loads the
database definition into memory. The positional first parameter specifies the name of the
database.

=over 4

=item dbName

Name of the database.

=item options

Table of options.

* B<dbType> type of database (currently C<mysql> for MySQL and C<pg> for PostgreSQL) (default C<mysql>)

* B<dataDir> directory containing the database definition file and the flat files used to load the data (default C<Data>)

* B<xmlFileName> name of the XML file containing the database definition (default C<SproutDBD.xml>)

* B<userData> user name and password, delimited by a slash (default same as SEED)

* B<port> connection port (default C<0>)

* B<sock> connection socket (default same as SEED)

* B<maxSegmentLength> maximum number of residues per feature segment, (default C<4500>)

* B<maxSequenceLength> maximum number of residues per sequence, (default C<8000>)

* B<noDBOpen> suppresses the connection to the database if TRUE, else FALSE

=back

For example, the following constructor call specifies a database named I<Sprout> and a user name of
I<fig> with a password of I<admin>. The database load files are in the directory
F</usr/fig/SproutData>.

C<< my $sprout = Sprout->new('Sprout', { userData =>; 'fig/admin', dataDir => '/usr/fig/SproutData' }); >>

=cut

sub new {
    # Get the parameters.
    my ($class, $dbName, $options) = @_;
    # Compute the DBD directory.
    my $dbd_dir = (defined($FIG_Config::dbd_dir) ? $FIG_Config::dbd_dir :
                                                  $FIG_Config::fig );
    # Compute the options. We do this by starting with a table of defaults and overwriting with
    # the incoming data.
    my $optionTable = Tracer::GetOptions({
                       dbType       => $FIG_Config::dbms,
                                                        # database type
                       dataDir      => $FIG_Config::sproutData,
                                                        # data file directory
                       xmlFileName  => "$dbd_dir/SproutDBD.xml",
                                                        # database definition file name
                       userData     => "$FIG_Config::dbuser/$FIG_Config::dbpass",
                                                        # user name and password
                       port         => $FIG_Config::dbport,
                                                        # database connection port
                       sock         => $FIG_Config::dbsock,
                       host         => $FIG_Config::dbhost,
                       maxSegmentLength => 4500,        # maximum feature segment length
                       maxSequenceLength => 8000,       # maximum contig sequence length
                       noDBOpen     => 0,               # 1 to suppress the database open
                      }, $options);
    # Get the data directory.
    my $dataDir = $optionTable->{dataDir};
    # Extract the user ID and password.
    $optionTable->{userData} =~ m!([^/]*)/(.*)$!;
    my ($userName, $password) = ($1, $2);
    # Connect to the database.
    my $dbh;
    if (! $optionTable->{noDBOpen}) {
        $dbh = DBKernel->new($optionTable->{dbType}, $dbName, $userName,
                                $password, $optionTable->{port}, $optionTable->{host}, $optionTable->{sock});
    }
    # Create the ERDB object.
    my $xmlFileName = "$optionTable->{xmlFileName}";
    my $retVal = ERDB::new($class, $dbh, $xmlFileName);
    # Add the option table and XML file name.
    $retVal->{_options} = $optionTable;
    $retVal->{_xmlName} = $xmlFileName;
    # Set up space for the group file data.
    $retVal->{groupHash} = undef;
    # Return it.
    return $retVal;
}

=head3 MaxSegment

C<< my $length = $sprout->MaxSegment(); >>

This method returns the maximum permissible length of a feature segment. The length is important
because it enables us to make reasonable guesses at how to find features inside a particular
contig region. For example, if the maximum length is 4000 and we're looking for a feature that
overlaps the region from 6000 to 7000 we know that the starting position must be between 2001
and 10999.

=cut
#: Return Type $;
sub MaxSegment {
    my ($self) = @_;
    return $self->{_options}->{maxSegmentLength};
}

=head3 MaxSequence

C<< my $length = $sprout->MaxSequence(); >>

This method returns the maximum permissible length of a contig sequence. A contig is broken
into sequences in order to save memory resources. In particular, when manipulating features,
we generally only need a few sequences in memory rather than the entire contig.

=cut
#: Return Type $;
sub MaxSequence {
    my ($self) = @_;
    return $self->{_options}->{maxSequenceLength};
}

=head3 Load

C<< $sprout->Load($rebuild); >>;

Load the database from files in the data directory, optionally re-creating the tables.

This method always deletes the data from the database before loading, even if the tables are not
re-created. The data is loaded into the relations from files in the data directory either having the
same name as the target relation with no extension or with an extension of C<.dtx>. Files without an
extension are used in preference to the files with an extension.

The files are loaded based on the presumption that each line of the file is a record in the
relation, and the individual fields are delimited by tabs. Tab and new-line characters inside
fields must be represented by the escape sequences C<\t> and C<\n>, respectively. The fields must
be presented in the order given in the relation tables produced by the L</ShowMetaData> method.

=over 4

=item rebuild

TRUE if the data tables need to be created or re-created, else FALSE

=item RETURN

Returns a statistical object containing the number of records read, the number of duplicates found,
the number of errors, and a list of the error messages.

=back

=cut
#: Return Type %;
sub Load {
    # Get the parameters.
    my ($self, $rebuild) = @_;
    # Load the tables from the data directory.
    my $retVal = $self->LoadTables($self->{_options}->{dataDir}, $rebuild);
    # Return the statistics.
    return $retVal;
}

=head3 LoadUpdate

C<< my $stats = $sprout->LoadUpdate($truncateFlag, \@tableList); >>

Load updates to one or more database tables. This method enables the client to make changes to one
or two tables without reloading the whole database. For each table, there must be a corresponding
file in the data directory, either with the same name as the table, or with a C<.dtx> suffix. So,
for example, to make updates to the B<FeatureTranslation> relation, there must be a
C<FeatureTranslation.dtx> file in the data directory. Unlike a full load, files without an extension
are not examined. This allows update files to co-exist with files from an original load.

=over 4

=item truncateFlag

TRUE if the tables should be rebuilt before loading, else FALSE. A value of TRUE therefore causes
current data and schema of the tables to be replaced, while a value of FALSE means the new data
is added to the existing data in the various relations.

=item tableList

List of the tables to be updated.

=item RETURN

Returns a statistical object containing the number of records read, the number of duplicates found,
the number of errors encountered, and a list of error messages.

=back

=cut
#: Return Type $%;
sub LoadUpdate {
    # Get the parameters.
    my ($self, $truncateFlag, $tableList) = @_;
    # Declare the return value.
    my $retVal = Stats->new();
    # Get the data directory.
    my $optionTable = $self->{_options};
    my $dataDir = $optionTable->{dataDir};
    # Loop through the incoming table names.
    for my $tableName (@{$tableList}) {
        # Find the table's file.
        my $fileName = LoadFileName($dataDir, $tableName);
        if (! $fileName) {
            Trace("No load file found for $tableName in $dataDir.") if T(0);
        } else {
            # Attempt to load this table.
            my $result = $self->LoadTable($fileName, $tableName, $truncateFlag);
            # Accumulate the resulting statistics.
            $retVal->Accumulate($result);
        }
    }
    # Return the statistics.
    return $retVal;
}

=head3 GenomeCounts

C<< my ($arch, $bact, $euk, $vir, $env, $unk) = $sprout->GenomeCounts($complete); >>

Count the number of genomes in each domain. If I<$complete> is TRUE, only complete
genomes will be included in the counts.

=over 4

=item complete

TRUE if only complete genomes are to be counted, FALSE if all genomes are to be
counted

=item RETURN

A six-element list containing the number of genomes in each of six categories--
Archaea, Bacteria, Eukaryota, Viral, Environmental, and Unknown, respectively.

=back

=cut

sub GenomeCounts {
    # Get the parameters.
    my ($self, $complete) = @_;
    # Set the filter based on the completeness flag.
    my $filter = ($complete ? "Genome(complete) = 1" : "");
    # Get all the genomes and the related taxonomy information.
    my @genomes = $self->GetAll(['Genome'], $filter, [], ['Genome(id)', 'Genome(taxonomy)']);
    # Clear the counters.
    my ($arch, $bact, $euk, $vir, $env, $unk) = (0, 0, 0, 0, 0, 0);
    # Loop through, counting the domains.
    for my $genome (@genomes) {
        if    ($genome->[1] =~ /^archaea/i)  { ++$arch }
        elsif ($genome->[1] =~ /^bacter/i)   { ++$bact }
        elsif ($genome->[1] =~ /^eukar/i)    { ++$euk }
        elsif ($genome->[1] =~ /^vir/i)      { ++$vir }
        elsif ($genome->[1] =~ /^env/i)      { ++$env }
        else  { ++$unk }
    }
    # Return the counts.
    return ($arch, $bact, $euk, $vir, $env, $unk);
}

=head3 ContigCount

C<< my $count = $sprout->ContigCount($genomeID); >>

Return the number of contigs for the specified genome ID.

=over 4

=item genomeID

ID of the genome whose contig count is desired.

=item RETURN

Returns the number of contigs for the specified genome.

=back

=cut

sub ContigCount {
    # Get the parameters.
    my ($self, $genomeID) = @_;
    # Get the contig count.
    my $retVal = $self->GetCount(['Contig', 'HasContig'], "HasContig(from-link) = ?", [$genomeID]);
    # Return the result.
    return $retVal;
}

=head3 GeneMenu

C<< my $selectHtml = $sprout->GeneMenu(\%attributes, $filterString, \@params, $selected); >>

Return an HTML select menu of genomes. Each genome will be an option in the menu,
and will be displayed by name with the ID and a contig count attached. The selection
value will be the genome ID. The genomes will be sorted by genus/species name.

=over 4

=item attributes

Reference to a hash mapping attributes to values for the SELECT tag generated.

=item filterString

A filter string for use in selecting the genomes. The filter string must conform
to the rules for the C<< ERDB->Get >> method.

=item params

Reference to a list of values to be substituted in for the parameter marks in
the filter string.

=item selected (optional)

ID of the genome to be initially selected.

=item fast (optional)

If specified and TRUE, the contig counts will be omitted to improve performance.

=item RETURN

Returns an HTML select menu with the specified genomes as selectable options.

=back

=cut

sub GeneMenu {
    # Get the parameters.
    my ($self, $attributes, $filterString, $params, $selected, $fast) = @_;
    my $slowMode = ! $fast;
    # Default to nothing selected. This prevents an execution warning if "$selected"
    # is undefined.
    $selected = "" unless defined $selected;
    Trace("Gene Menu called with slow mode \"$slowMode\" and selection \"$selected\".") if T(3);
    # Start the menu.
    my $retVal = "<select " .
        join(" ", map { "$_=\"$attributes->{$_}\"" } keys %{$attributes}) .
        ">\n";
    # Get the genomes.
    my @genomes = $self->GetAll(['Genome'], $filterString, $params, ['Genome(id)',
                                                                     'Genome(genus)',
                                                                     'Genome(species)',
                                                                     'Genome(unique-characterization)']);
    # Sort them by name.
    my @sorted = sort { lc("$a->[1] $a->[2]") cmp lc("$b->[1] $b->[2]") } @genomes;
    # Loop through the genomes, creating the option tags.
    for my $genomeData (@sorted) {
        # Get the data for this genome.
        my ($genomeID, $genus, $species, $strain) = @{$genomeData};
        # Get the contig count.
        my $contigInfo = "";
        if ($slowMode) {
            my $count = $self->ContigCount($genomeID);
            my $counting = ($count == 1 ? "contig" : "contigs");
            $contigInfo = "[$count $counting]";
        }
        # Find out if we're selected.
        my $selectOption = ($selected eq $genomeID ? " selected" : "");
        # Build the option tag.
        $retVal .= "<option value=\"$genomeID\"$selectOption>$genus $species $strain ($genomeID)$contigInfo</option>\n";
    }
    # Close the SELECT tag.
    $retVal .= "</select>\n";
    # Return the result.
    return $retVal;
}

=head3 Build

C<< $sprout->Build(); >>

Build the database. The database will be cleared and the tables re-created from the metadata.
This method is useful when a database is brand new or when the database definition has
changed.

=cut
#: Return Type ;
sub Build {
    # Get the parameters.
    my ($self) = @_;
    # Create the tables.
    $self->CreateTables();
}

=head3 NmpdrGenomeMenu

C<< my $htmlText = $sprout->NmpdrGenomeMenu(\%options, \@selected); >>

This method creates a hierarchical HTML menu for NMPDR genomes organized by category. The
category indicates the low-level NMPDR group. Organizing the genomes in this way makes it
easier to select all genomes from a particular category. 

=over 4

=item options

Reference to a hash containing the options to be applied to the C<SELECT> tag form the menu.
Typical options would include C<name> to specify the field name, C<multiple> to specify
that multiple selections are allowed, and C<size> to set the number of rows to display
in the menu.

=item selected

Reference to a list containing the IDs of the genomes to be pre-selected. If the menu
is not intended to allow multiple selections, the list should be a singleton. If the
list is empty, nothing will be pre-selected.

=item RETURN

Returns the HTML text to generate a C<SELECT> menu inside a form.

=back

=cut

sub NmpdrGenomeMenu {
    # Get the parameters.
    my ($self, $options, $selected) = @_;
    # Get a list of all the genomes in group order. In fact, we only need them ordered
    # by name (genus,species,strain), but putting primary-group in front enables us to
    # take advantage of an existing index.
    my @genomeList = $self->GetAll(['Genome'],
                                   "ORDER BY Genome(primary-group), Genome(genus), Genome(species), Genome(unique-characterization)",
                                   [], ['Genome(primary-group)', 'Genome(id)',
                                        'Genome(genus)', 'Genome(species)',
                                        'Genome(unique-characterization)']);
    # Create a hash to organize the genomes by group. Each group will contain a list of
    # 2-tuples, the first element being the genome ID and the second being the genome
    # name.
    my %groupHash = ();
    for my $genome (@genomeList) {
        # Get the genome data.
        my ($group, $genomeID, $genus, $species, $strain) = @{$genome};
        # Form the genome name.
        my $name = "$genus $species";
        if ($strain) {
            $name .= " $strain";
        }
        # Push the genome into the group's list.
        push @{$groupHash{$group}}, [$genomeID, $name];
    }
    # Now we are ready to unroll the menu out of the group hash. First, we sort the groups, putting
    # the supporting-genome group last.
    my @groups = sort grep { $_ ne $FIG_Config::otherGroup } keys %groupHash;
    push @groups, $FIG_Config::otherGroup;
    # Next, create a hash that specifies the pre-selected entries.
    my %selectedHash = map { $_ => 1 } @{$selected};
    # Create the SELECT tag and stuff it into the output array.
    my $select = "<" . join(" ", 'SELECT', map { "$_=\"$options->{$_}\"" } keys %{$options}) . ">";
    my @lines = ($select);
    # Loop through the groups.
    for my $group (@groups) {
        # Create the option group tag.
        my $tag = "<OPTGROUP name=\"$group\">";
        push @lines, "  $tag";
        # Get the genomes in the group.
        for my $genome (@{$groupHash{$group}}) {
            my ($genomeID, $name) = @{$genome};
            # See if it's selected.
            my $select = ($selectedHash{$genomeID} ? " selected" : "");
            # Generate the option tag.
            my $optionTag = "<OPTION value=\"$genomeID\"$select>$name</OPTION>";
            push @lines, "    $optionTag";
        }
        # Close the option group.
        push @lines, "  </OPTGROUP>";
    }
    # Close the SELECT tag.
    push @lines, "</SELECT>";
    # Assemble the lines into a string.
    my $retVal = join("\n", @lines, "");
    # Return the result.
    return $retVal;
}

=head3 Genomes

C<< my @genomes = $sprout->Genomes(); >>

Return a list of all the genome IDs.

=cut
#: Return Type @;
sub Genomes {
    # Get the parameters.
    my ($self) = @_;
    # Get all the genomes.
    my @retVal = $self->GetFlat(['Genome'], "", [], 'Genome(id)');
    # Return the list of IDs.
    return @retVal;
}

=head3 GenusSpecies

C<< my $infoString = $sprout->GenusSpecies($genomeID); >>

Return the genus, species, and unique characterization for a genome.

=over 4

=item genomeID

ID of the genome whose genus and species is desired

=item RETURN

Returns the genus and species of the genome, with the unique characterization (if any). If the genome
does not exist, returns an undefined value.

=back

=cut
#: Return Type $;
sub GenusSpecies {
    # Get the parameters.
    my ($self, $genomeID) = @_;
    # Get the data for the specified genome.
    my @values = $self->GetEntityValues('Genome', $genomeID, ['Genome(genus)', 'Genome(species)',
                                                              'Genome(unique-characterization)']);
    # Format the result and return it.
    my $retVal = join(' ', @values);
    return $retVal;
}

=head3 FeaturesOf

C<< my @features = $sprout->FeaturesOf($genomeID, $ftype); >>

Return a list of the features relevant to a specified genome.

=over 4

=item genomeID

Genome whose features are desired.

=item ftype

Type of feature desired. If omitted, all features will be returned.

=item RETURN

Returns a list of the feature IDs for features relevant to the genome. If the genome does not exist,
will return an empty list.

=back

=cut
#: Return Type @;
sub FeaturesOf {
    # Get the parameters.
    my ($self, $genomeID,$ftype) = @_;
    # Get the features we want.
    my @features;
    if (!$ftype) {
        @features = $self->GetFlat(['HasContig', 'IsLocatedIn'], "HasContig(from-link) = ?",
                                   [$genomeID], 'IsLocatedIn(from-link)');
    } else {
        @features = $self->GetFlat(['HasContig', 'IsLocatedIn', 'Feature'],
                            "HasContig(from-link) = ? AND Feature(feature-type) = ?",
                            [$genomeID, $ftype], 'IsLocatedIn(from-link)');
    }
    # Return the list with duplicates merged out. We need to merge out duplicates because
    # a feature will appear twice if it spans more than one contig.
    my @retVal = Tracer::Merge(@features);
    # Return the list of feature IDs.
    return @retVal;
}

=head3 FeatureLocation

C<< my @locations = $sprout->FeatureLocation($featureID); >>

Return the location of a feature in its genome's contig segments. In a list context, this method
will return a list of the locations. In a scalar context, it will return the locations as a space-
delimited string. Each location will be of the form I<contigID>C<_>I<begin>I<dir>I<len> where
I<begin> is the starting position, I<dir> is C<+> for a forward transcription or C<-> for a backward
transcription, and I<len> is the length. So, for example, C<1999.1_NC123_4000+200> describes a location
beginning at position 4000 of contig C<1999.1_NC123> and ending at position 4199. Similarly,
C<1999.1_NC123_2000-400> describes a location in the same contig starting at position 2000 and ending
at position 1601.

This process is complicated by the fact that we automatically split up feature segments longer than
the maximum segment length. When we find two segments that are adjacent to each other, we must
put them back together.

=over 4

=item featureID

FIG ID of the desired feature

=item RETURN

Returns a list of the feature's contig segments. The locations are returned as a list in a list
context and as a comma-delimited string in a scalar context.

=back

=cut
#: Return Type @;
#: Return Type $;
sub FeatureLocation {
    # Get the parameters.
    my ($self, $featureID) = @_;
    # Create a query for the feature locations.
    my $query = $self->Get(['IsLocatedIn'], "IsLocatedIn(from-link) = ? ORDER BY IsLocatedIn(locN)",
                           [$featureID]);
    # Create the return list.
    my @retVal = ();
    # Set up the variables used to determine if we have adjacent segments. This initial setup will
    # not match anything.
    my ($prevContig, $prevBeg, $prevDir, $prevLen) = ("", 0, "0", 0);
    # Loop through the query results, creating location specifiers.
    while (my $location = $query->Fetch()) {
        # Get the location parameters.
        my ($contigID, $beg, $dir, $len) = $location->Values(['IsLocatedIn(to-link)',
            'IsLocatedIn(beg)', 'IsLocatedIn(dir)', 'IsLocatedIn(len)']);
        # Check to see if we are adjacent to the previous segment.
        if ($prevContig eq $contigID && $dir eq $prevDir) {
            # Here the new segment is in the same direction on the same contig. Insure the
            # new segment's beginning is next to the old segment's end.
            if ($dir eq "-" && $beg + $len == $prevBeg) {
                # Here we're merging two backward blocks, so we keep the new begin point
                # and adjust the length.
                $len += $prevLen;
                # Pop the old segment off. The new one will replace it later.
                pop @retVal;
            } elsif ($dir eq "+" && $beg == $prevBeg + $prevLen) {
                # Here we need to merge two forward blocks. Adjust the beginning and
                # length values to include both segments.
                $beg = $prevBeg;
                $len += $prevLen;
                # Pop the old segment off. The new one will replace it later.
                pop @retVal;
            }
        }
        # Remember this specifier for the adjacent-segment test the next time through.
        ($prevContig, $prevBeg, $prevDir, $prevLen) = ($contigID, $beg, $dir, $len);
        # Compute the initial base pair.
        my $start = ($dir eq "+" ? $beg : $beg + $len - 1);
        # Add the specifier to the list.
        push @retVal, "${contigID}_$start$dir$len";
    }
    # Return the list in the format indicated by the context.
    return (wantarray ? @retVal : join(',', @retVal));
}

=head3 ParseLocation

C<< my ($contigID, $start, $dir, $len) = Sprout::ParseLocation($location); >>

Split a location specifier into the contig ID, the starting point, the direction, and the
length.

=over 4

=item location

A location specifier (see L</FeatureLocation> for a description).

=item RETURN

Returns a list containing the contig ID, the start position, the direction (C<+> or C<->),
and the length indicated by the incoming location specifier.

=back

=cut
#: Return Type @;
sub ParseLocation {
    # Get the parameter. Note that if we're called as an instance method, we ignore
    # the first parameter.
    shift if UNIVERSAL::isa($_[0],__PACKAGE__);
    my ($location) = @_;
    # Parse it into segments.
    $location =~ /^(.+)_(\d+)([+\-_])(\d+)$/;
    my ($contigID, $start, $dir, $len) = ($1, $2, $3, $4);
    # If the direction is an underscore, convert it to a + or -.
    if ($dir eq "_") {
        if ($start < $len) {
            $dir = "+";
            $len = $len - $start + 1;
        } else {
            $dir = "-";
            $len = $start - $len + 1;
        }
    }
    # Return the result.
    return ($contigID, $start, $dir, $len);
}



=head3 PointLocation

C<< my $found = Sprout::PointLocation($location, $point); >>

Return the offset into the specified location of the specified point on the contig. If
the specified point is before the location, a negative value will be returned. If it is
beyond the location, an undefined value will be returned. It is assumed that the offset
is for the location's contig. The location can either be new-style (using a C<+> or C<->
and a length) or old-style (using C<_> and start and end positions.

=over 4

=item location

A location specifier (see L</FeatureLocation> for a description).

=item point

The offset into the contig of the point in which we're interested.

=item RETURN

Returns the offset inside the specified location of the specified point, a negative
number if the point is before the location, or an undefined value if the point is past
the location. If the length of the location is 0, this method will B<always> denote
that it is outside the location. The offset will always be relative to the left-most
position in the location.

=back

=cut
#: Return Type $;
sub PointLocation {
    # Get the parameter. Note that if we're called as an instance method, we ignore
    # the first parameter.
    shift if UNIVERSAL::isa($_[0],__PACKAGE__);
    my ($location, $point) = @_;
    # Parse out the location elements. Note that this works on both old-style and new-style
    # locations.
    my ($contigID, $start, $dir, $len) = ParseLocation($location);
    # Declare the return variable.
    my $retVal;
    # Compute the offset. The computation is dependent on the direction of the location.
    my $offset = (($dir == '+') ? $point - $start : $point - ($start - $len + 1));
    # Return the offset if it's valid.
    if ($offset < $len) {
        $retVal = $offset;
    }
    # Return the offset found.
    return $retVal;
}

=head3 DNASeq

C<< my $sequence = $sprout->DNASeq(\@locationList); >>

This method returns the DNA sequence represented by a list of locations. The list of locations
should be of the form returned by L</featureLocation> when in a list context. In other words,
each location is of the form I<contigID>C<_>I<begin>I<dir>I<end>.

For example, the following would return the DNA sequence for contig C<83333.1:NC_000913>
between positions 1401 and 1532, inclusive.

    my $sequence = $sprout->DNASeq('83333.1:NC_000913_1401_1532');

=over 4

=item locationList

List of location specifiers, each in the form I<contigID>C<_>I<begin>I<dir>I<len> or
I<contigID>C<_>I<begin>C<_>I<end> (see L</FeatureLocation> for more about this format).

=item RETURN

Returns a string of nucleotides corresponding to the DNA segments in the location list.

=back

=cut
#: Return Type $;
sub DNASeq {
    # Get the parameters.
    my ($self, $locationList) = @_;
    # Create the return string.
    my $retVal = "";
    # Loop through the locations.
    for my $location (@{$locationList}) {
        # Set up a variable to contain the DNA at this location.
        my $locationDNA = "";
        # Parse out the contig ID, the beginning point, the direction, and the end point.
        my ($contigID, $beg, $dir, $len) = ParseLocation($location);
        # Now we must create a query to return all the sequences in the contig relevant to the region
        # specified. First, we compute the start and stop points when reading through the sequences.
        # For a forward transcription, the start point is the beginning; for a backward transcription,
        # the start point is the ending. Note that in the latter case we must reverse the DNA string
        # before putting it in the return value.
        my ($start, $stop);
        Trace("Parse of \"$location\" is $beg$dir$len.") if T(SDNA => 4);
        if ($dir eq "+") {
            $start = $beg;
            $stop = $beg + $len - 1;
        } else {
            $start = $beg - $len + 1;
            $stop = $beg;
        }
        Trace("Looking for sequences containing $start through $stop.") if T(SDNA => 4);
        my $query = $self->Get(['IsMadeUpOf','Sequence'],
            "IsMadeUpOf(from-link) = ? AND IsMadeUpOf(start-position) + IsMadeUpOf(len) > ? AND " .
            " IsMadeUpOf(start-position) <= ? ORDER BY IsMadeUpOf(start-position)",
            [$contigID, $start, $stop]);
        # Loop through the sequences.
        while (my $sequence = $query->Fetch()) {
            # Determine whether the location starts, stops, or continues through this sequence.
            my ($startPosition, $sequenceData, $sequenceLength) =
                $sequence->Values(['IsMadeUpOf(start-position)', 'Sequence(sequence)',
                                   'IsMadeUpOf(len)']);
            my $stopPosition = $startPosition + $sequenceLength;
            Trace("Sequence is from $startPosition to $stopPosition.") if T(SDNA => 4);
            # Figure out the start point and length of the relevant section.
            my $pos1 = ($start < $startPosition ? 0 : $start - $startPosition);
            my $len1 = ($stopPosition < $stop ? $stopPosition : $stop) + 1 - $startPosition - $pos1;
            Trace("Position is $pos1 for length $len1.") if T(SDNA => 4);
            # Add the relevant data to the location data.
            $locationDNA .= substr($sequenceData, $pos1, $len1);
        }
        # Add this location's data to the return string. Note that we may need to reverse it.
        if ($dir eq '+') {
            $retVal .= $locationDNA;
        } else {
            $retVal .= FIG::reverse_comp($locationDNA);
        }
    }
    # Return the result.
    return $retVal;
}

=head3 AllContigs

C<< my @idList = $sprout->AllContigs($genomeID); >>

Return a list of all the contigs for a genome.

=over 4

=item genomeID

Genome whose contigs are desired.

=item RETURN

Returns a list of the IDs for the genome's contigs.

=back

=cut
#: Return Type @;
sub AllContigs {
    # Get the parameters.
    my ($self, $genomeID) = @_;
    # Ask for the genome's Contigs.
    my @retVal = $self->GetFlat(['HasContig'], "HasContig(from-link) = ?", [$genomeID],
                                'HasContig(to-link)');
    # Return the list of Contigs.
    return @retVal;
}

=head3 GenomeLength

C<< my $length = $sprout->GenomeLength($genomeID); >>

Return the length of the specified genome in base pairs.

=over 4

=item genomeID

ID of the genome whose base pair count is desired.

=item RETURN

Returns the number of base pairs in all the contigs of the specified
genome.

=back

=cut

sub GenomeLength {
    # Get the parameters.
    my ($self, $genomeID) = @_;
    # Declare the return variable.
    my $retVal = 0;
    # Get the genome's contig sequence lengths.
    my @lens = $self->GetFlat(['HasContig', 'IsMadeUpOf'], 'HasContig(from-link) = ?',
                       [$genomeID], 'IsMadeUpOf(len)');
    # Sum the lengths.
    map { $retVal += $_ } @lens;
    # Return the result.
    return $retVal;
}

=head3 FeatureCount

C<< my $count = $sprout->FeatureCount($genomeID, $type); >>

Return the number of features of the specified type in the specified genome.

=over 4

=item genomeID

ID of the genome whose feature count is desired.

=item type

Type of feature to count (eg. C<peg>, C<rna>, etc.).

=item RETURN

Returns the number of features of the specified type for the specified genome.

=back

=cut

sub FeatureCount {
    # Get the parameters.
    my ($self, $genomeID, $type) = @_;
    # Compute the count.
    my $retVal = $self->GetCount(['HasFeature', 'Feature'],
                                "HasFeature(from-link) = ? AND Feature(feature-type) = ?",
                                [$genomeID, $type]);
    # Return the result.
    return $retVal;
}

=head3 GenomeAssignments

C<< my $fidHash = $sprout->GenomeAssignments($genomeID); >>

Return a list of a genome's assigned features. The return hash will contain each
assigned feature of the genome mapped to the text of its most recent functional
assignment.

=over 4

=item genomeID

ID of the genome whose functional assignments are desired.

=item RETURN

Returns a reference to a hash which maps each feature to its most recent
functional assignment.

=back

=cut

sub GenomeAssignments {
    # Get the parameters.
    my ($self, $genomeID) = @_;
    # Declare the return variable.
    my $retVal = {};
    # Query the genome's features and annotations. We'll put the oldest annotations
    # first so that the last assignment to go into the hash will be the correct one.
    my $query = $self->Get(['HasFeature', 'IsTargetOfAnnotation', 'Annotation'],
                           "HasFeature(from-link) = ? ORDER BY Annotation(time)",
                           [$genomeID]);
    # Loop through the annotations.
    while (my $data = $query->Fetch) {
        # Get the feature ID and annotation text.
        my ($fid, $annotation) = $data->Values(['HasFeature(to-link)',
                                                'Annotation(annotation)']);
        # Check to see if this is an assignment. Note that the user really
        # doesn't matter to us, other than we use it to determine whether or
        # not this is an assignment.
        my ($user, $assignment) = _ParseAssignment('fig', $annotation);
        if ($user) {
            # Here it's an assignment. We put it in the return hash, overwriting
            # any older assignment that might be present.
            $retVal->{$fid} = $assignment;
        }
    }
    # Return the result.
    return $retVal;
}

=head3 ContigLength

C<< my $length = $sprout->ContigLength($contigID); >>

Compute the length of a contig.

=over 4

=item contigID

ID of the contig whose length is desired.

=item RETURN

Returns the number of positions in the contig.

=back

=cut
#: Return Type $;
sub ContigLength {
    # Get the parameters.
    my ($self, $contigID) = @_;
    # Get the contig's last sequence.
    my $query = $self->Get(['IsMadeUpOf'],
        "IsMadeUpOf(from-link) = ? ORDER BY IsMadeUpOf(start-position) DESC",
        [$contigID]);
    my $sequence = $query->Fetch();
    # Declare the return value.
    my $retVal = 0;
    # Set it from the sequence data, if any.
    if ($sequence) {
        my ($start, $len) = $sequence->Values(['IsMadeUpOf(start-position)', 'IsMadeUpOf(len)']);
        $retVal = $start + $len - 1;
    }
    # Return the result.
    return $retVal;
}

=head3 ClusterPEGs

C<< my $clusteredList = $sprout->ClusterPEGs($sub, \@pegs); >>

Cluster the PEGs in a list according to the cluster coding scheme of the specified
subsystem. In order for this to work properly, the subsystem object must have
been used recently to retrieve the PEGs using the B<get_pegs_from_cell> method.
This causes the cluster numbers to be pulled into the subsystem's color hash.
If a PEG is not found in the color hash, it will not appear in the output
sequence.

=over 4

=item sub

Sprout subsystem object for the relevant subsystem, from the L</get_subsystem>
method.

=item pegs

Reference to the list of PEGs to be clustered.

=item RETURN

Returns a list of the PEGs, grouped into smaller lists by cluster number.

=back

=cut
#: Return Type $@@;
sub ClusterPEGs {
    # Get the parameters.
    my ($self, $sub, $pegs) = @_;
    # Declare the return variable.
    my $retVal = [];
    # Loop through the PEGs, creating arrays for each cluster.
    for my $pegID (@{$pegs}) {
        my $clusterNumber = $sub->get_cluster_number($pegID);
        # Only proceed if the PEG is in a cluster.
        if ($clusterNumber >= 0) {
            # Push this PEG onto the sub-list for the specified cluster number.
            push @{$retVal->[$clusterNumber]}, $pegID;
        }
    }
    # Return the result.
    return $retVal;
}

=head3 GenesInRegion

C<< my (\@featureIDList, $beg, $end) = $sprout->GenesInRegion($contigID, $start, $stop); >>

List the features which overlap a specified region in a contig.

=over 4

=item contigID

ID of the contig containing the region of interest.

=item start

Offset of the first residue in the region of interest.

=item stop

Offset of the last residue in the region of interest.

=item RETURN

Returns a three-element list. The first element is a list of feature IDs for the features that
overlap the region of interest. The second and third elements are the minimum and maximum
locations of the features provided on the specified contig. These may extend outside
the start and stop values. The first element (that is, the list of features) is sorted
roughly by location.

=back

=cut
#: Return Type @@;
sub GenesInRegion {
    # Get the parameters.
    my ($self, $contigID, $start, $stop) = @_;
    # Get the maximum segment length.
    my $maximumSegmentLength = $self->MaxSegment;
    # Create a hash to receive the feature list. We use a hash so that we can eliminate
    # duplicates easily. The hash key will be the feature ID. The value will be a two-element
    # containing the minimum and maximum offsets. We will use the offsets to sort the results
    # when we're building the result set.
    my %featuresFound = ();
    # Prime the values we'll use for the returned beginning and end.
    my @initialMinMax = ($self->ContigLength($contigID), 0);
    my ($min, $max) = @initialMinMax;
    # Create a table of parameters for each query. Each query looks for features travelling in
    # a particular direction. The query parameters include the contig ID, the feature direction,
    # the lowest possible start position, and the highest possible start position. This works
    # because each feature segment length must be no greater than the maximum segment length.
    my %queryParms = (forward => [$contigID, '+', $start - $maximumSegmentLength + 1, $stop],
                      reverse => [$contigID, '-', $start, $stop + $maximumSegmentLength - 1]);
    # Loop through the query parameters.
    for my $parms (values %queryParms) {
        # Create the query.
        my $query = $self->Get(['IsLocatedIn'],
            "IsLocatedIn(to-link)= ? AND IsLocatedIn(dir) = ? AND IsLocatedIn(beg) >= ? AND IsLocatedIn(beg) <= ?",
            $parms);
        # Loop through the feature segments found.
        while (my $segment = $query->Fetch) {
            # Get the data about this segment.
            my ($featureID, $dir, $beg, $len) = $segment->Values(['IsLocatedIn(from-link)',
                'IsLocatedIn(dir)', 'IsLocatedIn(beg)', 'IsLocatedIn(len)']);
            # Determine if this feature actually overlaps the region. The query insures that
            # this will be the case if the segment is the maximum length, so to fine-tune
            # the results we insure that the inequality from the query holds using the actual
            # length.
            my ($found, $end) = (0, 0);
            if ($dir eq '+') {
                $end = $beg + $len;
                if ($end >= $start) {
                    # Denote we found a useful feature.
                    $found = 1;
                }
            } elsif ($dir eq '-') {
                # Note we switch things around so that the beginning is to the left of the
                # ending.
                ($beg, $end) = ($beg - $len, $beg);
                if ($beg <= $stop) {
                    # Denote we found a useful feature.
                    $found = 1;
                }
            }
            if ($found) {
                # Here we need to record the feature and update the minima and maxima. First,
                # get the current entry for the specified feature.
                my ($loc1, $loc2) = (exists $featuresFound{$featureID} ? @{$featuresFound{$featureID}} :
                                     @initialMinMax);
                # Merge the current segment's begin and end into the feature begin and end and the
                # global min and max.
                if ($beg < $loc1) {
                    $loc1 = $beg;
                    $min = $beg if $beg < $min;
                }
                if ($end > $loc2) {
                    $loc2 = $end;
                    $max = $end if $end > $max;
                }
                # Store the entry back into the hash table.
                $featuresFound{$featureID} = [$loc1, $loc2];
            }
        }
    }
    # Now we must compute the list of the IDs for the features found. We start with a list
    # of midpoints / feature ID pairs. (It's not really a midpoint, it's twice the midpoint,
    # but the result of the sort will be the same.)
    my @list = map { [$featuresFound{$_}->[0] + $featuresFound{$_}->[1], $_] } keys %featuresFound;
    # Now we sort by midpoint and yank out the feature IDs.
    my @retVal = map { $_->[1] } sort { $a->[0] <=> $b->[0] } @list;
    # Return it along with the min and max.
    return (\@retVal, $min, $max);
}

=head3 FType

C<< my $ftype = $sprout->FType($featureID); >>

Return the type of a feature.

=over 4

=item featureID

ID of the feature whose type is desired.

=item RETURN

A string indicating the type of feature (e.g. peg, rna). If the feature does not exist, returns an
undefined value.

=back

=cut
#: Return Type $;
sub FType {
    # Get the parameters.
    my ($self, $featureID) = @_;
    # Get the specified feature's type.
    my ($retVal) = $self->GetEntityValues('Feature', $featureID, ['Feature(feature-type)']);
    # Return the result.
    return $retVal;
}

=head3 FeatureAnnotations

C<< my @descriptors = $sprout->FeatureAnnotations($featureID, $rawFlag); >>

Return the annotations of a feature.

=over 4

=item featureID

ID of the feature whose annotations are desired.

=item rawFlag

If TRUE, the annotation timestamps will be returned in raw form; otherwise, they
will be returned in human-readable form.

=item RETURN

Returns a list of annotation descriptors. Each descriptor is a hash with the following fields.

* B<featureID> ID of the relevant feature.

* B<timeStamp> time the annotation was made.

* B<user> ID of the user who made the annotation

* B<text> text of the annotation.

=back

=cut
#: Return Type @%;
sub FeatureAnnotations {
    # Get the parameters.
    my ($self, $featureID, $rawFlag) = @_;
    # Create a query to get the feature's annotations and the associated users.
    my $query = $self->Get(['IsTargetOfAnnotation', 'Annotation', 'MadeAnnotation'],
                           "IsTargetOfAnnotation(from-link) = ?", [$featureID]);
    # Create the return list.
    my @retVal = ();
    # Loop through the annotations.
    while (my $annotation = $query->Fetch) {
        # Get the fields to return.
        my ($featureID, $timeStamp, $user, $text) =
            $annotation->Values(['IsTargetOfAnnotation(from-link)',
                                 'Annotation(time)', 'MadeAnnotation(from-link)',
                                 'Annotation(annotation)']);
        # Convert the time, if necessary.
        if (! $rawFlag) {
            $timeStamp = FriendlyTimestamp($timeStamp);
        }
        # Assemble them into a hash.
        my $annotationHash = { featureID => $featureID,
                               timeStamp => $timeStamp,
                               user => $user, text => $text };
        # Add it to the return list.
        push @retVal, $annotationHash;
    }
    # Return the result list.
    return @retVal;
}

=head3 AllFunctionsOf

C<< my %functions = $sprout->AllFunctionsOf($featureID); >>

Return all of the functional assignments for a particular feature. The data is returned as a
hash of functional assignments to user IDs. A functional assignment is a type of annotation,
Functional assignments are described in the L</ParseAssignment> function. Its worth noting that
we cannot filter on the content of the annotation itself because it's a text field; however,
this is not a big problem because most features only have a small number of annotations.
Finally, if a single user has multiple functional assignments, we will only keep the most
recent one.

=over 4

=item featureID

ID of the feature whose functional assignments are desired.

=item RETURN

Returns a hash mapping the user IDs to functional assignment IDs.

=back

=cut
#: Return Type %;
sub AllFunctionsOf {
    # Get the parameters.
    my ($self, $featureID) = @_;
    # Get all of the feature's annotations.
    my @query = $self->GetAll(['IsTargetOfAnnotation', 'Annotation', 'MadeAnnotation'],
                            "IsTargetOfAnnotation(from-link) = ?",
                            [$featureID], ['Annotation(time)', 'Annotation(annotation)',
                                           'MadeAnnotation(from-link)']);
    # Declare the return hash.
    my %retVal;
    # Now we sort the assignments by timestamp in reverse.
    my @sortedQuery = sort { -($a->[0] <=> $b->[0]) } @query;
    # Loop until we run out of annotations.
    for my $annotation (@sortedQuery) {
        # Get the annotation fields.
        my ($timeStamp, $text, $user) = @{$annotation};
        # Check to see if this is a functional assignment.
        my ($actualUser, $function) = _ParseAssignment($user, $text);
        if ($actualUser && ! exists $retVal{$actualUser}) {
            # Here it is a functional assignment and there has been no
            # previous assignment for this user, so we stuff it in the
            # return hash.
            $retVal{$actualUser} = $function;
        }
    }
    # Return the hash of assignments found.
    return %retVal;
}

=head3 FunctionOf

C<< my $functionText = $sprout->FunctionOf($featureID, $userID); >>

Return the most recently-determined functional assignment of a particular feature.

The functional assignment is handled differently depending on the type of feature. If
the feature is identified by a FIG ID (begins with the string C<fig|>), then a functional
assignment is a type of annotation. The format of an assignment is described in
L</ParseAssignment>. Its worth noting that we cannot filter on the content of the
annotation itself because it's a text field; however, this is not a big problem because
most features only have a small number of annotations.

Each user has an associated list of trusted users. The assignment returned will be the most
recent one by at least one of the trusted users. If no trusted user list is available, then
the specified user and FIG are considered trusted. If the user ID is omitted, only FIG
is trusted.

If the feature is B<not> identified by a FIG ID, then the functional assignment
information is taken from the B<ExternalAliasFunc> table. If the table does
not contain an entry for the feature, an undefined value is returned.

=over 4

=item featureID

ID of the feature whose functional assignment is desired.

=item userID (optional)

ID of the user whose function determination is desired. If omitted, only the latest
C<FIG> assignment will be returned.

=item RETURN

Returns the text of the assigned function.

=back

=cut
#: Return Type $;
sub FunctionOf {
    # Get the parameters.
    my ($self, $featureID, $userID) = @_;
    # Declare the return value.
    my $retVal;
    # Determine the ID type.
    if ($featureID =~ m/^fig\|/) {
        # Here we have a FIG feature ID. We must build the list of trusted
        # users.
        my %trusteeTable = ();
        # Check the user ID.
        if (!$userID) {
            # No user ID, so only FIG is trusted.
            $trusteeTable{FIG} = 1;
        } else {
            # Add this user's ID.
            $trusteeTable{$userID} = 1;
            # Look for the trusted users in the database.
            my @trustees = $self->GetFlat(['IsTrustedBy'], 'IsTrustedBy(from-link) = ?', [$userID], 'IsTrustedBy(to-link)');
            if (! @trustees) {
                # None were found, so build a default list.
                $trusteeTable{FIG} = 1;
            } else {
                # Otherwise, put all the trustees in.
                for my $trustee (@trustees) {
                    $trusteeTable{$trustee} = 1;
                }
            }
        }
        # Build a query for all of the feature's annotations, sorted by date.
        my $query = $self->Get(['IsTargetOfAnnotation', 'Annotation', 'MadeAnnotation'],
                               "IsTargetOfAnnotation(from-link) = ? ORDER BY Annotation(time) DESC",
                               [$featureID]);
        my $timeSelected = 0;
        # Loop until we run out of annotations.
        while (my $annotation = $query->Fetch()) {
            # Get the annotation text.
            my ($text, $time, $user) = $annotation->Values(['Annotation(annotation)',
                                                     'Annotation(time)', 'MadeAnnotation(from-link)']);
            # Check to see if this is a functional assignment for a trusted user.
            my ($actualUser, $function) = _ParseAssignment($user, $text);
            Trace("Assignment user is $actualUser, text is $function.") if T(4);
            if ($actualUser) {
                # Here it is a functional assignment. Check the time and the user
                # name. The time must be recent and the user must be trusted.
                if ((exists $trusteeTable{$actualUser}) && ($time > $timeSelected)) {
                    $retVal = $function;
                    $timeSelected = $time;
                }
            }
        }
    } else {
        # Here we have a non-FIG feature ID. In this case the user ID does not
        # matter. We simply get the information from the External Alias Function
        # table.
        ($retVal) = $self->GetEntityValues('ExternalAliasFunc', $featureID, ['ExternalAliasFunc(func)']);
    }
    # Return the assignment found.
    return $retVal;
}

=head3 FunctionsOf

C<< my @functionList = $sprout->FunctionOf($featureID, $userID); >>

Return the functional assignments of a particular feature.

The functional assignment is handled differently depending on the type of feature. If
the feature is identified by a FIG ID (begins with the string C<fig|>), then a functional
assignment is a type of annotation. The format of an assignment is described in
L</ParseAssignment>. Its worth noting that we cannot filter on the content of the
annotation itself because it's a text field; however, this is not a big problem because
most features only have a small number of annotations.

If the feature is B<not> identified by a FIG ID, then the functional assignment
information is taken from the B<ExternalAliasFunc> table. If the table does
not contain an entry for the feature, an empty list is returned.

=over 4

=item featureID

ID of the feature whose functional assignments are desired.

=item RETURN

Returns a list of 2-tuples, each consisting of a user ID and the text of an assignment by
that user.

=back

=cut
#: Return Type @@;
sub FunctionsOf {
    # Get the parameters.
    my ($self, $featureID) = @_;
    # Declare the return value.
    my @retVal = ();
    # Determine the ID type.
    if ($featureID =~ m/^fig\|/) {
        # Here we have a FIG feature ID. We must build the list of trusted
        # users.
        my %trusteeTable = ();
        # Build a query for all of the feature's annotations, sorted by date.
        my $query = $self->Get(['IsTargetOfAnnotation', 'Annotation', 'MadeAnnotation'],
                               "IsTargetOfAnnotation(from-link) = ? ORDER BY Annotation(time) DESC",
                               [$featureID]);
        my $timeSelected = 0;
        # Loop until we run out of annotations.
        while (my $annotation = $query->Fetch()) {
            # Get the annotation text.
            my ($text, $time, $user) = $annotation->Values(['Annotation(annotation)',
                                                            'Annotation(time)',
                                                            'MadeAnnotation(user)']);
            # Check to see if this is a functional assignment for a trusted user.
            my ($actualUser, $function) = _ParseAssignment($user, $text);
            if ($actualUser) {
                # Here it is a functional assignment.
                push @retVal, [$actualUser, $function];
            }
        }
    } else {
        # Here we have a non-FIG feature ID. In this case the user ID does not
        # matter. We simply get the information from the External Alias Function
        # table.
        my @assignments = $self->GetEntityValues('ExternalAliasFunc', $featureID,
                                                 ['ExternalAliasFunc(func)']);
        push @retVal, map { ['master', $_] } @assignments;
    }
    # Return the assignments found.
    return @retVal;
}

=head3 BBHList

C<< my $bbhHash = $sprout->BBHList($genomeID, \@featureList); >>

Return a hash mapping the features in a specified list to their bidirectional best hits
on a specified target genome.

=over 4

=item genomeID

ID of the genome from which the best hits should be taken.

=item featureList

List of the features whose best hits are desired.

=item RETURN

Returns a reference to a hash that maps the IDs of the incoming features to the best hits
on the target genome.

=back

=cut
#: Return Type %;
sub BBHList {
    # Get the parameters.
    my ($self, $genomeID, $featureList) = @_;
    # Create the return structure.
    my %retVal = ();
    # Loop through the incoming features.
    for my $featureID (@{$featureList}) {
        # Ask the server for the feature's best hit.
        my @bbhData = FIGRules::BBHData($featureID);
        # Peel off the BBHs found.
        my @found = ();
        for my $bbh (@bbhData) {
            push @found, $bbh->[0];
        }
        $retVal{$featureID} = \@found;
    }
    # Return the mapping.
    return \%retVal;
}

=head3 SimList

C<< my %similarities = $sprout->SimList($featureID, $count); >>

Return a list of the similarities to the specified feature.

This method just returns the bidirectional best hits for performance reasons.

=over 4

=item featureID

ID of the feature whose similarities are desired.

=item count

Maximum number of similar features to be returned, or C<0> to return them all.

=back

=cut
#: Return Type %;
sub SimList {
    # Get the parameters.
    my ($self, $featureID, $count) = @_;
    # Ask for the best hits.
    my @lists = FIGRules::BBHData($featureID);
    # Create the return value.
    my %retVal = ();
    for my $tuple (@lists) {
        $retVal{$tuple->[0]} = $tuple->[1];
    }
    # Return the result.
    return %retVal;
}

=head3 IsComplete

C<< my $flag = $sprout->IsComplete($genomeID); >>

Return TRUE if the specified genome is complete, else FALSE.

=over 4

=item genomeID

ID of the genome whose completeness status is desired.

=item RETURN

Returns TRUE if the genome is complete, FALSE if it is incomplete, and C<undef> if it is
not found.

=back

=cut
#: Return Type $;
sub IsComplete {
    # Get the parameters.
    my ($self, $genomeID) = @_;
    # Declare the return variable.
    my $retVal;
    # Get the genome's data.
    my $genomeData = $self->GetEntity('Genome', $genomeID);
    if ($genomeData) {
        # The genome exists, so get the completeness flag.
        ($retVal) = $genomeData->Value('Genome(complete)');
    }
    # Return the result.
    return $retVal;
}

=head3 FeatureAliases

C<< my @aliasList = $sprout->FeatureAliases($featureID); >>

Return a list of the aliases for a specified feature.

=over 4

=item featureID

ID of the feature whose aliases are desired.

=item RETURN

Returns a list of the feature's aliases. If the feature is not found or has no aliases, it will
return an empty list.

=back

=cut
#: Return Type @;
sub FeatureAliases {
    # Get the parameters.
    my ($self, $featureID) = @_;
    # Get the desired feature's aliases
    my @retVal = $self->GetEntityValues('Feature', $featureID, ['Feature(alias)']);
    # Return the result.
    return @retVal;
}

=head3 GenomeOf

C<< my $genomeID = $sprout->GenomeOf($featureID); >>

Return the genome that contains a specified feature or contig.

=over 4

=item featureID

ID of the feature or contig whose genome is desired.

=item RETURN

Returns the ID of the genome for the specified feature or contig. If the feature or contig is not
found, returns an undefined value.

=back

=cut
#: Return Type $;
sub GenomeOf {
    # Get the parameters.
    my ($self, $featureID) = @_;
    # Create a query to find the genome associated with the incoming ID.
    my $query = $self->Get(['IsLocatedIn', 'HasContig'], "IsLocatedIn(from-link) = ? OR HasContig(to-link) = ?",
                           [$featureID, $featureID]);
    # Declare the return value.
    my $retVal;
    # Get the genome ID.
    if (my $relationship = $query->Fetch()) {
        ($retVal) = $relationship->Value('HasContig(from-link)');
    }
    # Return the value found.
    return $retVal;
}

=head3 CoupledFeatures

C<< my %coupleHash = $sprout->CoupledFeatures($featureID); >>

Return the features functionally coupled with a specified feature. Features are considered
functionally coupled if they tend to be clustered on the same chromosome.

=over 4

=item featureID

ID of the feature whose functionally-coupled brethren are desired.

=item RETURN

A hash mapping the functionally-coupled feature IDs to the coupling score.

=back

=cut
#: Return Type %;
sub CoupledFeatures {
    # Get the parameters.
    my ($self, $featureID) = @_;
    Trace("Looking for features coupled to $featureID.") if T(coupling => 3);
    # Create a query to retrieve the functionally-coupled features.
    my $query = $self->Get(['ParticipatesInCoupling', 'Coupling'],
                           "ParticipatesInCoupling(from-link) = ?", [$featureID]);
    # This value will be set to TRUE if we find at least one coupled feature.
    my $found = 0;
    # Create the return hash.
    my %retVal = ();
    # Retrieve the relationship records and store them in the hash.
    while (my $clustering = $query->Fetch()) {
        # Get the ID and score of the coupling.
        my ($couplingID, $score) = $clustering->Values(['Coupling(id)',
                                                        'Coupling(score)']);
        Trace("$featureID coupled with score $score to ID $couplingID.") if T(coupling => 4);
        # Get the other feature that participates in the coupling.
        my ($otherFeatureID) = $self->GetFlat(['ParticipatesInCoupling'],
                                           "ParticipatesInCoupling(to-link) = ? AND ParticipatesInCoupling(from-link) <> ?",
                                           [$couplingID, $featureID], 'ParticipatesInCoupling(from-link)');
        Trace("$couplingID target feature is $otherFeatureID.") if T(coupling => 4);
        # Attach the other feature's score to its ID.
        $retVal{$otherFeatureID} = $score;
        $found = 1;
    }
    # Functional coupling is reflexive. If we found at least one coupled feature, we must add
    # the incoming feature as well.
    if ($found) {
        $retVal{$featureID} = 9999;
    }
    # Return the hash.
    return %retVal;
}

=head3 CouplingEvidence

C<< my @evidence = $sprout->CouplingEvidence($peg1, $peg2); >>

Return the evidence for a functional coupling.

A pair of features is considered evidence of a coupling between two other
features if they occur close together on a contig and both are similar to
the coupled features. So, if B<A1> and B<A2> are close together on a contig,
B<B1> and B<B2> are considered evidence for the coupling if (1) B<B1> and
B<B2> are close together, (2) B<B1> is similar to B<A1>, and (3) B<B2> is
similar to B<A2>.

The score of a coupling is determined by the number of pieces of evidence
that are considered I<representative>. If several evidence items belong to
a group of genomes that are close to each other, only one of those items
is considered representative. The other evidence items are presumed to be
there because of the relationship between the genomes rather than because
the two proteins generated by the features have a related functionality.

Each evidence item is returned as a three-tuple in the form C<[>I<$peg1a>C<,>
I<$peg2a>C<,> I<$rep>C<]>, where I<$peg1a> is similar to I<$peg1>, I<$peg2a>
is similar to I<$peg2>, and I<$rep> is TRUE if the evidence is representative
and FALSE otherwise.

=over 4

=item peg1

ID of the feature of interest.

=item peg2

ID of a feature functionally coupled to the feature of interest.

=item RETURN

Returns a list of 3-tuples. Each tuple consists of a feature similar to the feature
of interest, a feature similar to the functionally coupled feature, and a flag
that is TRUE for a representative piece of evidence and FALSE otherwise.

=back

=cut
#: Return Type @@;
sub CouplingEvidence {
    # Get the parameters.
    my ($self, $peg1, $peg2) = @_;
    # Declare the return variable.
    my @retVal = ();
    # Our first task is to find out the nature of the coupling: whether or not
    # it exists, its score, and whether the features are stored in the same
    # order as the ones coming in.
    my ($couplingID, $inverted, $score) = $self->GetCoupling($peg1, $peg2);
    # Only proceed if a coupling exists.
    if ($couplingID) {
        # Determine the ordering to place on the evidence items. If we're
        # inverted, we want to see feature 2 before feature 1 (descending); otherwise,
        # we want feature 1 before feature 2 (normal).
        Trace("Coupling evidence for ($peg1, $peg2) with inversion flag $inverted.") if T(Coupling => 4);
        my $ordering = ($inverted ? "DESC" : "");
        # Get the coupling evidence.
        my @evidenceList = $self->GetAll(['IsEvidencedBy', 'PCH', 'UsesAsEvidence'],
                                          "IsEvidencedBy(from-link) = ? ORDER BY PCH(id), UsesAsEvidence(pos) $ordering",
                                          [$couplingID],
                                          ['PCH(used)', 'UsesAsEvidence(to-link)']);
        # Loop through the evidence items. Each piece of evidence is represented by two
        # positions in the evidence list, one for each feature on the other side of the
        # evidence link. If at some point we want to generalize to couplings with
        # more than two positions, this section of code will need to be re-done.
        while (@evidenceList > 0) {
            my $peg1Data = shift @evidenceList;
            my $peg2Data = shift @evidenceList;
            Trace("Peg 1 is " . $peg1Data->[1] . " and Peg 2 is " . $peg2Data->[1] . ".") if T(Coupling => 4);
            push @retVal, [$peg1Data->[1], $peg2Data->[1], $peg1Data->[0]];
        }
        Trace("Last index in evidence result is is $#retVal.") if T(Coupling => 4);
    }
    # Return the result.
    return @retVal;
}

=head3 GetCoupling

C<< my ($couplingID, $inverted, $score) = $sprout->GetCoupling($peg1, $peg2); >>

Return the coupling (if any) for the specified pair of PEGs. If a coupling
exists, we return the coupling ID along with an indicator of whether the
coupling is stored as C<(>I<$peg1>C<, >I<$peg2>C<)> or C<(>I<$peg2>C<, >I<$peg1>C<)>.
In the second case, we say the coupling is I<inverted>. The importance of an
inverted coupling is that the PEGs in the evidence will appear in reverse order.

=over 4

=item peg1

ID of the feature of interest.

=item peg2

ID of the potentially coupled feature.

=item RETURN

Returns a three-element list. The first element contains the database ID of
the coupling. The second element is FALSE if the coupling is stored in the
database in the caller specified order and TRUE if it is stored in the
inverted order. The third element is the coupling's score. If the coupling
does not exist, all three list elements will be C<undef>.

=back

=cut
#: Return Type $%@;
sub GetCoupling {
    # Get the parameters.
    my ($self, $peg1, $peg2) = @_;
    # Declare the return values. We'll start with the coupling ID and undefine the
    # flag and score until we have more information.
    my ($retVal, $inverted, $score) = ($self->CouplingID($peg1, $peg2), undef, undef);
    # Find the coupling data.
    my @pegs = $self->GetAll(['Coupling', 'ParticipatesInCoupling'],
                                 "Coupling(id) = ? ORDER BY ParticipatesInCoupling(pos)",
                                 [$retVal], ["ParticipatesInCoupling(from-link)", "Coupling(score)"]);
    # Check to see if we found anything.
    if (!@pegs) {
        Trace("No coupling found.") if T(Coupling => 4);
        # No coupling, so undefine the return value.
        $retVal = undef;
    } else {
        # We have a coupling! Get the score and check for inversion.
        $score = $pegs[0]->[1];
        my $firstFound = $pegs[0]->[0];
        $inverted = ($firstFound ne $peg1);
        Trace("Coupling score is $score. First peg is $firstFound, peg 1 is $peg1.") if T(Coupling => 4);
    }
    # Return the result.
    return ($retVal, $inverted, $score);
}

=head3 GetSynonymGroup

C<< my $id = $sprout->GetSynonymGroup($fid); >>

Return the synonym group name for the specified feature.

=over 4

=item fid

ID of the feature whose synonym group is desired.

=item RETURN

The name of the synonym group to which the feature belongs. If the feature does
not belong to a synonym group, the feature ID itself is returned.

=back

=cut

sub GetSynonymGroup {
    # Get the parameters.
    my ($self, $fid) = @_;
    # Declare the return variable.
    my $retVal;
    # Find the synonym group.
    my @groups = $self->GetFlat(['IsSynonymGroupFor'], "IsSynonymGroupFor(to-link) = ?",
                                   [$fid], 'IsSynonymGroupFor(from-link)');
    # Check to see if we found anything.
    if (@groups) {
        $retVal = $groups[0];
    } else {
        $retVal = $fid;
    }
    # Return the result.
    return $retVal;
}

=head3 GetBoundaries

C<< my ($contig, $beg, $end) = $sprout->GetBoundaries(@locList); >>

Determine the begin and end boundaries for the locations in a list. All of the
locations must belong to the same contig and have mostly the same direction in
order for this method to produce a meaningful result. The resulting
begin/end pair will contain all of the bases in any of the locations.

=over 4

=item locList

List of locations to process.

=item RETURN

Returns a 3-tuple consisting of the contig ID, the beginning boundary,
and the ending boundary. The beginning boundary will be left of the
end for mostly-forward locations and right of the end for mostly-backward
locations.

=back

=cut

sub GetBoundaries {
    # Get the parameters.
    my ($self, @locList) = @_;
    # Set up the counters used to determine the most popular direction.
    my %counts = ( '+' => 0, '-' => 0 );
    # Get the last location and parse it.
    my $locObject = BasicLocation->new(pop @locList);
    # Prime the loop with its data.
    my ($contig, $beg, $end) = ($locObject->Contig, $locObject->Left, $locObject->Right);
    # Count its direction.
    $counts{$locObject->Dir}++;
    # Loop through the remaining locations. Note that in most situations, this loop
    # will not iterate at all, because most of the time we will be dealing with a
    # singleton list.
    for my $loc (@locList) {
        # Create a location object.
        my $locObject = BasicLocation->new($loc);
        # Count the direction.
        $counts{$locObject->Dir}++;
        # Get the left end and the right end.
        my $left = $locObject->Left;
        my $right = $locObject->Right;
        # Merge them into the return variables.
        if ($left < $beg) {
            $beg = $left;
        }
        if ($right > $end) {
            $end = $right;
        }
    }
    # If the most common direction is reverse, flip the begin and end markers.
    if ($counts{'-'} > $counts{'+'}) {
        ($beg, $end) = ($end, $beg);
    }
    # Return the result.
    return ($contig, $beg, $end);
}

=head3 CouplingID

C<< my $couplingID = $sprout->CouplingID($peg1, $peg2); >>

Return the coupling ID for a pair of feature IDs.

The coupling ID is currently computed by joining the feature IDs in
sorted order with a space. Client modules (that is, modules which
use Sprout) should not, however, count on this always being the
case. This method provides a way for abstracting the concept of a
coupling ID. All that we know for sure about it is that it can be
generated easily from the feature IDs and the order of the IDs
in the parameter list does not matter (i.e. C<CouplingID("a1", "b1")>
will have the same value as C<CouplingID("b1", "a1")>.

=over 4

=item peg1

First feature of interest.

=item peg2

Second feature of interest.

=item RETURN

Returns the ID that would be used to represent a functional coupling of
the two specified PEGs.

=back

=cut
#: Return Type $;
sub CouplingID {
    my ($self, @pegs) = @_;
    return $self->DigestKey(join " ", sort @pegs);
}

=head3 ReadFasta

C<< my %sequenceData = Sprout::ReadFasta($fileName, $prefix); >>

Read sequence data from a FASTA-format file. Each sequence in a FASTA file is represented by
one or more lines of data. The first line begins with a > character and contains an ID.
The remaining lines contain the sequence data in order.

=over 4

=item fileName

Name of the FASTA file.

=item prefix (optional)

Prefix to be put in front of each ID found.

=item RETURN

Returns a hash that maps each ID to its sequence.

=back

=cut
#: Return Type %;
sub ReadFasta {
    # Get the parameters.
    my ($fileName, $prefix) = @_;
    # Create the return hash.
    my %retVal = ();
    # Open the file for input.
    open FASTAFILE, '<', $fileName;
    # Declare the ID variable and clear the sequence accumulator.
    my $sequence = "";
    my $id = "";
    # Loop through the file.
    while (<FASTAFILE>) {
        # Get the current line.
        my $line = $_;
        # Check for a header line.
        if ($line =~ m/^>\s*(.+?)(\s|\n)/) {
            # Here we have a new header. Store the current sequence if we have one.
            if ($id) {
                $retVal{$id} = lc $sequence;
            }
            # Clear the sequence accumulator and save the new ID.
            ($id, $sequence) = ("$prefix$1", "");
        } else {
            # Here we have a data line, so we add it to the sequence accumulator.
            # First, we get the actual data out. Note that we normalize to lower
            # case.
            $line =~ /^\s*(.*?)(\s|\n)/;
            $sequence .= $1;
        }
    }
    # Flush out the last sequence (if any).
    if ($sequence) {
        $retVal{$id} = lc $sequence;
    }
    # Close the file.
    close FASTAFILE;
    # Return the hash constructed from the file.
    return %retVal;
}

=head3 FormatLocations

C<< my @locations = $sprout->FormatLocations($prefix, \@locations, $oldFormat); >>

Insure that a list of feature locations is in the Sprout format. The Sprout feature location
format is I<contig>_I<beg*len> where I<*> is C<+> for a forward gene and C<-> for a backward
gene. The old format is I<contig>_I<beg>_I<end>. If a feature is in the new format already,
it will not be changed; otherwise, it will be converted. This method can also be used to
perform the reverse task-- insuring that all the locations are in the old format.

=over 4

=item prefix

Prefix to be put in front of each contig ID (or an empty string if the contig ID should not
be changed.

=item locations

List of locations to be normalized.

=item oldFormat

TRUE to convert the locations to the old format, else FALSE

=item RETURN

Returns a list of updated location descriptors.

=back

=cut
#: Return Type @;
sub FormatLocations {
    # Get the parameters.
    my ($self, $prefix, $locations, $oldFormat) = @_;
    # Create the return list.
    my @retVal = ();
    # Check to see if any locations were passed in.
    if ($locations eq '') {
        Confess("No locations specified.");
    } else {
        # Loop through the locations, converting them to the new format.
        for my $location (@{$locations}) {
            # Parse the location elements.
            my ($contig, $beg, $dir, $len) = ParseLocation($location);
            # Process according to the desired output format.
            if (!$oldFormat) {
                # Here we're producing the new format. Add the location to the return list.
                push @retVal, "$prefix${contig}_$beg$dir$len";
            } elsif ($dir eq '+') {
                # Here we're producing the old format and it's a forward gene.
                my $end = $beg + $len - 1;
                push @retVal, "$prefix${contig}_${beg}_$end";
            } else {
                # Here we're producting the old format and it's a backward gene.
                my $end = $beg - $len + 1;
                push @retVal, "$prefix${contig}_${beg}_$end";
            }
        }
    }
    # Return the normalized list.
    return @retVal;
}

=head3 DumpData

C<< $sprout->DumpData(); >>

Dump all the tables to tab-delimited DTX files. The files will be stored in the data directory.

=cut

sub DumpData {
    # Get the parameters.
    my ($self) = @_;
    # Get the data directory name.
    my $outputDirectory = $self->{_options}->{dataDir};
    # Dump the relations.
    $self->DumpRelations($outputDirectory);
}

=head3 XMLFileName

C<< my $fileName = $sprout->XMLFileName(); >>

Return the name of this database's XML definition file.

=cut
#: Return Type $;
sub XMLFileName {
    my ($self) = @_;
    return $self->{_xmlName};
}

=head3 Insert

C<< $sprout->Insert($objectType, \%fieldHash); >>

Insert an entity or relationship instance into the database. The entity or relationship of interest
is defined by a type name and then a hash of field names to values. Field values in the primary
relation are represented by scalars. (Note that for relationships, the primary relation is
the B<only> relation.) Field values for the other relations comprising the entity are always
list references. For example, the following line inserts an inactive PEG feature named
C<fig|188.1.peg.1> with aliases C<ZP_00210270.1> and C<gi|46206278>.

C<< $sprout->Insert('Feature', { id => 'fig|188.1.peg.1', active => 0, feature-type => 'peg', alias => ['ZP_00210270.1', 'gi|46206278']}); >>

The next statement inserts a C<HasProperty> relationship between feature C<fig|158879.1.peg.1> and
property C<4> with an evidence URL of C<http://seedu.uchicago.edu/query.cgi?article_id=142>.

C<< $sprout->InsertObject('HasProperty', { 'from-link' => 'fig|158879.1.peg.1', 'to-link' => 4, evidence => 'http://seedu.uchicago.edu/query.cgi?article_id=142'}); >>

=over 4

=item newObjectType

Type name of the entity or relationship to insert.

=item fieldHash

Hash of field names to values.

=back

=cut
#: Return Type ;
sub Insert {
    # Get the parameters.
    my ($self, $objectType, $fieldHash) = @_;
    # Call the underlying method.
    $self->InsertObject($objectType, $fieldHash);
}

=head3 Annotate

C<< my $ok = $sprout->Annotate($fid, $timestamp, $user, $text); >>

Annotate a feature. This inserts an Annotation record into the database and links it to the
specified feature and user.

=over 4

=item fid

ID of the feature to be annotated.

=item timestamp

Numeric timestamp to apply to the annotation. This is concatenated to the feature ID to create the
key.

=item user

ID of the user who is making the annotation.

=item text

Text of the annotation.

=item RETURN

Returns 1 if successful, 2 if an error occurred.

=back

=cut
#: Return Type $;
sub Annotate {
    # Get the parameters.
    my ($self, $fid, $timestamp, $user, $text) = @_;
    # Create the annotation ID.
    my $aid = "$fid:$timestamp";
    # Insert the Annotation object.
    my $retVal = $self->Insert('Annotation', { id => $aid, time => $timestamp, annotation => $text });
    if ($retVal) {
        # Connect it to the user.
        $retVal = $self->Insert('MadeAnnotation', { 'from-link' => $user, 'to-link' => $aid });
        if ($retVal) {
            # Connect it to the feature.
            $retVal = $self->Insert('IsTargetOfAnnotation', { 'from-link' => $fid,
                                                             'to-link' => $aid });
        }
    }
    # Return the success indicator.
    return $retVal;
}

=head3 AssignFunction

C<< my $ok = $sprout->AssignFunction($featureID, $user, $function, $assigningUser); >>

This method assigns a function to a feature. Functions are a special type of annotation. The general
format is described in L</ParseAssignment>.

=over 4

=item featureID

ID of the feature to which the assignment is being made.

=item user

Name of the user group making the assignment, such as C<kegg> or C<fig>.

=item function

Text of the function being assigned.

=item assigningUser (optional)

Name of the individual user making the assignment. If omitted, defaults to the user group.

=item RETURN

Returns 1 if successful, 0 if an error occurred.

=back

=cut
#: Return Type $;
sub AssignFunction {
    # Get the parameters.
    my ($self, $featureID, $user, $function, $assigningUser) = @_;
    # Default the assigning user.
    if (! $assigningUser) {
        $assigningUser = $user;
    }
    # Create an annotation string from the parameters.
    my $annotationText = "$assigningUser\nset $user function to\n$function";
    # Get the current time.
    my $now = time;
    # Declare the return variable.
    my $retVal = 1;
    # Locate the genome containing the feature.
    my $genome = $self->GenomeOf($featureID);
    if (!$genome) {
        # Here the genome was not found. This probably means the feature ID is invalid.
        Trace("No genome found for feature $featureID.") if T(0);
        $retVal = 0;
    } else {
        # Here we know we have a feature with a genome. Store the annotation.
        $retVal = $self->Annotate($featureID, $now, $user, $annotationText);
    }
    # Return the success indicator.
    return $retVal;
}

=head3 FeaturesByAlias

C<< my @features = $sprout->FeaturesByAlias($alias); >>

Returns a list of features with the specified alias. The alias is parsed to determine
the type of the alias. A string of digits is a GenBack ID and a string of exactly 6
alphanumerics is a UniProt ID. A built-in FIG.pm method is used to analyze the alias
string and attach the necessary prefix. If the result is a FIG ID then it is returned
unmodified; otherwise, we look for an alias.

=over 4

=item alias

Alias whose features are desired.

=item RETURN

Returns a list of the features with the given alias.

=back

=cut
#: Return Type @;
sub FeaturesByAlias {
    # Get the parameters.
    my ($self, $alias) = @_;
    # Declare the return variable.
    my @retVal = ();
    # Parse the alias.
    my ($mappedAlias, $flag) = FIGRules::NormalizeAlias($alias);
    # If it's a FIG alias, we're done.
    if ($flag) {
        push @retVal, $mappedAlias;
    } else {
        # Here we have a non-FIG alias. Get the features with the normalized alias.
        @retVal = $self->GetFlat(['Feature'], 'Feature(alias) = ?', [$mappedAlias], 'Feature(id)');
    }
    # Return the result.
    return @retVal;
}

=head3 FeatureTranslation

C<< my $translation = $sprout->FeatureTranslation($featureID); >>

Return the translation of a feature.

=over 4

=item featureID

ID of the feature whose translation is desired

=item RETURN

Returns the translation of the specified feature.

=back

=cut
#: Return Type $;
sub FeatureTranslation {
    # Get the parameters.
    my ($self, $featureID) = @_;
    # Get the specified feature's translation.
    my ($retVal) = $self->GetEntityValues("Feature", $featureID, ['Feature(translation)']);
    return $retVal;
}

=head3 Taxonomy

C<< my @taxonomyList = $sprout->Taxonomy($genome); >>

Return the taxonomy of the specified genome. This will be in the form of a list
containing the various classifications in order from domain (eg. C<Bacteria>, C<Archaea>,
or C<Eukaryote>) to sub-species. For example,

C<< (Bacteria, Proteobacteria, Gammaproteobacteria, Enterobacteriales, Enterobacteriaceae, Escherichia, Escherichia coli, Escherichia coli K12) >>

=over 4

=item genome

ID of the genome whose taxonomy is desired.

=item RETURN

Returns a list containing all the taxonomy classifications for the specified genome's organism.

=back

=cut
#: Return Type @;
sub Taxonomy {
    # Get the parameters.
    my ($self, $genome) = @_;
    # Find the specified genome's taxonomy string.
    my ($list) = $self->GetEntityValues('Genome', $genome, ['Genome(taxonomy)']);
    # Declare the return variable.
    my @retVal = ();
    # If we found the genome, return its taxonomy string.
    if ($list) {
        @retVal = split /\s*;\s*/, $list;
    } else {
        Trace("Genome \"$genome\" does not have a taxonomy in the database.\n") if T(0);
    }
    # Return the value found.
    return @retVal;
}

=head3 CrudeDistance

C<< my $distance = $sprout->CrudeDistance($genome1, $genome2); >>

Returns a crude estimate of the distance between two genomes. The distance is construed so
that it will be 0 for genomes with identical taxonomies and 1 for genomes from different domains.

=over 4

=item genome1

ID of the first genome to compare.

=item genome2

ID of the second genome to compare.

=item RETURN

Returns a value from 0 to 1, with 0 meaning identical organisms, and 1 meaning organisms from
different domains.

=back

=cut
#: Return Type $;
sub CrudeDistance {
    # Get the parameters.
    my ($self, $genome1, $genome2) = @_;
    # Insure that the distance is commutative by sorting the genome IDs.
    my ($genomeA, $genomeB);
    if ($genome2 < $genome2) {
        ($genomeA, $genomeB) = ($genome1, $genome2);
    } else {
        ($genomeA, $genomeB) = ($genome2, $genome1);
    }
    my @taxA = $self->Taxonomy($genomeA);
    my @taxB = $self->Taxonomy($genomeB);
    # Initialize the distance to 1. We'll reduce it each time we find a match between the
    # taxonomies.
    my $retVal = 1.0;
    # Initialize the subtraction amount. This amount determines the distance reduction caused
    # by a mismatch at the current level.
    my $v = 0.5;
    # Loop through the taxonomies.
    for (my $i = 0; ($i < @taxA) && ($i < @taxB) && ($taxA[$i] eq $taxB[$i]); $i++) {
        $retVal -= $v;
        $v /= 2;
    }
    return $retVal;
}

=head3 RoleName

C<< my $roleName = $sprout->RoleName($roleID); >>

Return the descriptive name of the role with the specified ID. In general, a role
will only have a descriptive name if it is coded as an EC number.

=over 4

=item roleID

ID of the role whose description is desired.

=item RETURN

Returns the descriptive name of the desired role.

=back

=cut
#: Return Type $;
sub RoleName {
    # Get the parameters.
    my ($self, $roleID) = @_;
    # Get the specified role's name.
    my ($retVal) = $self->GetEntityValues('Role', $roleID, ['Role(name)']);
    # Use the ID if the role has no name.
    if (!$retVal) {
        $retVal = $roleID;
    }
    # Return the name.
    return $retVal;
}

=head3 RoleDiagrams

C<< my @diagrams = $sprout->RoleDiagrams($roleID); >>

Return a list of the diagrams containing a specified functional role.

=over 4

=item roleID

ID of the role whose diagrams are desired.

=item RETURN

Returns a list of the IDs for the diagrams that contain the specified functional role.

=back

=cut
#: Return Type @;
sub RoleDiagrams {
    # Get the parameters.
    my ($self, $roleID) = @_;
    # Query for the diagrams.
    my @retVal = $self->GetFlat(['RoleOccursIn'], "RoleOccursIn(from-link) = ?", [$roleID],
                                'RoleOccursIn(to-link)');
    # Return the result.
    return @retVal;
}

=head3 GetProperties

C<< my @list = $sprout->GetProperties($fid, $key, $value, $url); >>

Return a list of the properties with the specified characteristics.

Properties are arbitrary key-value pairs associated with a feature. (At some point they
will also be associated with genomes.) A property value is represented by a 4-tuple of
the form B<($fid, $key, $value, $url)>. These exactly correspond to the parameter

=over 4

=item fid

ID of the feature possessing the property.

=item key

Name or key of the property.

=item value

Value of the property.

=item url

URL of the document that indicated the property should have this particular value, or an
empty string if no such document exists.

=back

The parameters act as a filter for the desired data. Any non-null parameter will
automatically match all the tuples returned. So, specifying just the I<$fid> will
return all the properties of the specified feature; similarly, specifying the I<$key>
and I<$value> parameters will return all the features having the specified property
value.

A single property key can have many values, representing different ideas about the
feature in question. For example, one paper may declare that a feature C<fig|83333.1.peg.10> is
virulent, and another may declare that it is not virulent. A query about the virulence of
C<fig|83333.1.peg.10> would be coded as

    my @list = $sprout->GetProperties('fig|83333.1.peg.10', 'virulence', '', '');

Here the I<$value> and I<$url> fields are left blank, indicating that those fields are
not to be filtered. The tuples returned would be

    ('fig|83333.1.peg.10', 'virulence', 'yes', 'http://www.somewhere.edu/first.paper.pdf')
    ('fig|83333.1.peg.10', 'virulence', 'no', 'http://www.somewhere.edu/second.paper.pdf')

=cut
#: Return Type @@;
sub GetProperties {
    # Get the parameters.
    my ($self, @parms) = @_;
    # Declare the return variable.
    my @retVal = ();
    # Now we need to create a WHERE clause that will get us the data we want. First,
    # we create a list of the columns containing the data for each parameter.
    my @colNames = ('HasProperty(from-link)', 'Property(property-name)',
                    'Property(property-value)', 'HasProperty(evidence)');
    # Now we build the WHERE clause and the list of parameter values.
    my @where = ();
    my @values = ();
    for (my $i = 0; $i <= $#colNames; $i++) {
        my $parm = $parms[$i];
        if (defined $parm && ($parm ne '')) {
            push @where, "$colNames[$i] = ?";
            push @values, $parm;
        }
    }
    # Format the WHERE clause.
    my $filter = (@values > 0 ? (join " AND ", @where) : undef);
    # Ask for all the propertie values with the desired characteristics.
    my $query = $self->Get(['HasProperty', 'Property'], $filter, \@values);
    while (my $valueObject = $query->Fetch()) {
        my @tuple = $valueObject->Values(\@colNames);
        push @retVal, \@tuple;
    }
    # Return the result.
    return @retVal;
}

=head3 FeatureProperties

C<< my @properties = $sprout->FeatureProperties($featureID); >>

Return a list of the properties for the specified feature. Properties are key-value pairs
that specify special characteristics of the feature. For example, a property could indicate
that a feature is essential to the survival of the organism or that it has benign influence
on the activities of a pathogen. Each property is returned as a triple of the form
C<($key,$value,$url)>, where C<$key> is the property name, C<$value> is its value (commonly
a 1 or a 0, but possibly a string or a floating-point value), and C<$url> is a string describing
the web address or citation in which the property's value for the feature was identified.

=over 4

=item featureID

ID of the feature whose properties are desired.

=item RETURN

Returns a list of triples, each triple containing the property name, its value, and a URL or
citation.

=back

=cut
#: Return Type @@;
sub FeatureProperties {
    # Get the parameters.
    my ($self, $featureID) = @_;
    # Get the properties.
    my @retVal = $self->GetAll(['HasProperty', 'Property'], "HasProperty(from-link) = ?", [$featureID],
                            ['Property(property-name)', 'Property(property-value)',
                             'HasProperty(evidence)']);
    # Return the resulting list.
    return @retVal;
}

=head3 DiagramName

C<< my $diagramName = $sprout->DiagramName($diagramID); >>

Return the descriptive name of a diagram.

=over 4

=item diagramID

ID of the diagram whose description is desired.

=item RETURN

Returns the descripive name of the specified diagram.

=back

=cut
#: Return Type $;
sub DiagramName {
    # Get the parameters.
    my ($self, $diagramID) = @_;
    # Get the specified diagram's name and return it.
    my ($retVal) = $self->GetEntityValues('Diagram', $diagramID, ['Diagram(name)']);
    return $retVal;
}

=head3 MergedAnnotations

C<< my @annotationList = $sprout->MergedAnnotations(\@list); >>

Returns a merged list of the annotations for the features in a list. Each annotation is
represented by a 4-tuple of the form C<($fid, $timestamp, $userID, $annotation)>, where
C<$fid> is the ID of a feature, C<$timestamp> is the time at which the annotation was made,
C<$userID> is the ID of the user who made the annotation, and C<$annotation> is the annotation
text. The list is sorted by timestamp.

=over 4

=item list

List of the IDs for the features whose annotations are desired.

=item RETURN

Returns a list of annotation descriptions sorted by the annotation time.

=back

=cut
#: Return Type @;
sub MergedAnnotations {
    # Get the parameters.
    my ($self, $list) = @_;
    # Create a list to hold the annotation tuples found.
    my @tuples = ();
    # Loop through the features in the input list.
    for my $fid (@{$list}) {
        # Create a list of this feature's annotation tuples.
        my @newTuples = $self->GetAll(['IsTargetOfAnnotation', 'Annotation', 'MadeAnnotation'],
                               "IsTargetOfAnnotation(from-link) = ?", [$fid],
                               ['IsTargetOfAnnotation(from-link)', 'Annotation(time)',
                                'MadeAnnotation(from-link)', 'Annotation(annotation)']);
        # Put it in the result list.
        push @tuples, @newTuples;
    }
    # Sort the result list by timestamp.
    my @retVal = sort { $a->[1] <=> $b->[1] } @tuples;
    # Loop through and make the time stamps friendly.
    for my $tuple (@retVal) {
        $tuple->[1] = FriendlyTimestamp($tuple->[1]);
    }
    # Return the sorted list.
    return @retVal;
}

=head3 RoleNeighbors

C<< my @roleList = $sprout->RoleNeighbors($roleID); >>

Returns a list of the roles that occur in the same diagram as the specified role. Because
diagrams and roles are in a many-to-many relationship with each other, the list is
essentially the set of roles from all of the maps that contain the incoming role. Such
roles are considered neighbors because they are used together in cellular subsystems.

=over 4

=item roleID

ID of the role whose neighbors are desired.

=item RETURN

Returns a list containing the IDs of the roles that are related to the incoming role.

=back

=cut
#: Return Type @;
sub RoleNeighbors {
    # Get the parameters.
    my ($self, $roleID) = @_;
    # Get all the diagrams containing this role.
    my @diagrams = $self->GetFlat(['RoleOccursIn'], "RoleOccursIn(from-link) = ?", [$roleID],
                                  'RoleOccursIn(to-link)');
    # Create the return list.
    my @retVal = ();
    # Loop through the diagrams.
    for my $diagramID (@diagrams) {
        # Get all the roles in this diagram.
        my @roles = $self->GetFlat(['RoleOccursIn'], "RoleOccursIn(to-link) = ?", [$diagramID],
                                   'RoleOccursIn(from-link)');
        # Add them to the return list.
        push @retVal, @roles;
    }
    # Merge the duplicates from the list.
    return Tracer::Merge(@retVal);
}

=head3 FeatureLinks

C<< my @links = $sprout->FeatureLinks($featureID); >>

Return a list of the web hyperlinks associated with a feature. The web hyperlinks are
to external websites describing either the feature itself or the organism containing it
and are represented in raw HTML.

=over 4

=item featureID

ID of the feature whose links are desired.

=item RETURN

Returns a list of the web links for this feature.

=back

=cut
#: Return Type @;
sub FeatureLinks {
    # Get the parameters.
    my ($self, $featureID) = @_;
    # Get the feature's links.
    my @retVal = $self->GetEntityValues('Feature', $featureID, ['Feature(link)']);
    # Return the feature's links.
    return @retVal;
}

=head3 SubsystemsOf

C<< my %subsystems = $sprout->SubsystemsOf($featureID); >>

Return a hash describing all the subsystems in which a feature participates. Each subsystem is mapped
to the roles the feature performs.

=over 4

=item featureID

ID of the feature whose subsystems are desired.

=item RETURN

Returns a hash mapping all the feature's subsystems to a list of the feature's roles.

=back

=cut
#: Return Type %@;
sub SubsystemsOf {
    # Get the parameters.
    my ($self, $featureID) = @_;
    # Get the subsystem list.
    my @subsystems = $self->GetAll(['ContainsFeature', 'HasSSCell', 'IsRoleOf'],
                                    "ContainsFeature(to-link) = ?", [$featureID],
                                    ['HasSSCell(from-link)', 'IsRoleOf(from-link)']);
    # Create the return value.
    my %retVal = ();
    # Build a hash to weed out duplicates. Sometimes the same PEG and role appears
    # in two spreadsheet cells.
    my %dupHash = ();
    # Loop through the results, adding them to the hash.
    for my $record (@subsystems) {
        # Get this subsystem and role.
        my ($subsys, $role) = @{$record};
        # Insure it's the first time for both.
        my $dupKey = "$subsys\n$role";
        if (! exists $dupHash{"$subsys\n$role"}) {
            $dupHash{$dupKey} = 1;
            push @{$retVal{$subsys}}, $role;
        }
    }
    # Return the hash.
    return %retVal;
}

=head3 SubsystemList

C<< my @subsystems = $sprout->SubsystemList($featureID); >>

Return a list containing the names of the subsystems in which the specified
feature participates. Unlike L</SubsystemsOf>, this method only returns the
subsystem names, not the roles.

=over 4

=item featureID

ID of the feature whose subsystem names are desired.

=item RETURN

Returns a list of the names of the subsystems in which the feature participates.

=back

=cut
#: Return Type @;
sub SubsystemList {
    # Get the parameters.
    my ($self, $featureID) = @_;
    # Get the list of names.
    my @retVal = $self->GetFlat(['ContainsFeature', 'HasSSCell'], "ContainsFeature(to-link) = ?",
                                [$featureID], 'HasSSCell(from-link)');
    # Return the result.
    return @retVal;
}

=head3 GenomeSubsystemData

C<< my %featureData = $sprout->GenomeSubsystemData($genomeID); >>

Return a hash mapping genome features to their subsystem roles.

=over 4

=item genomeID

ID of the genome whose subsystem feature map is desired.

=item RETURN

Returns a hash mapping each feature of the genome to a list of 2-tuples. Eacb
2-tuple contains a subsystem name followed by a role ID.

=back

=cut

sub GenomeSubsystemData {
    # Get the parameters.
    my ($self, $genomeID) = @_;
    # Declare the return variable.
    my %retVal = ();
    # Get a list of the genome features that participate in subsystems. For each
    # feature we get its spreadsheet cells and the corresponding roles.
    my @roleData = $self->GetAll(['HasFeature', 'ContainsFeature', 'IsRoleOf'],
                             "HasFeature(from-link) = ?", [$genomeID],
                             ['HasFeature(to-link)', 'IsRoleOf(to-link)', 'IsRoleOf(from-link)']);
    # Now we get a list of the spreadsheet cells and their associated subsystems. Subsystems
    # with an unknown variant code (-1) are skipped. Note the genome ID is at both ends of the
    # list. We use it at the beginning to get all the spreadsheet cells for the genome and
    # again at the end to filter out participation in subsystems with a negative variant code.
    my @cellData = $self->GetAll(['IsGenomeOf', 'HasSSCell', 'ParticipatesIn'],
                                 "IsGenomeOf(from-link) = ? AND ParticipatesIn(variant-code) >= 0 AND ParticipatesIn(from-link) = ?",
                                 [$genomeID, $genomeID], ['HasSSCell(to-link)', 'HasSSCell(from-link)']);
    # Now "@roleData" lists the spreadsheet cell and role for each of the genome's features.
    # "@cellData" lists the subsystem name for each of the genome's spreadsheet cells. We
    # link these two lists together to create the result. First, we want a hash mapping
    # spreadsheet cells to subsystem names.
    my %subHash = map { $_->[0] => $_->[1] } @cellData;
    # We loop through @cellData to build the hash.
    for my $roleEntry (@roleData) {
        # Get the data for this feature and cell.
        my ($fid, $cellID, $role) = @{$roleEntry};
        # Check for a subsystem name.
        my $subsys = $subHash{$cellID};
        if ($subsys) {
            # Insure this feature has an entry in the return hash.
            if (! exists $retVal{$fid}) { $retVal{$fid} = []; }
            # Merge in this new data.
            push @{$retVal{$fid}}, [$subsys, $role];
        }
    }
    # Return the result.
    return %retVal;
}

=head3 RelatedFeatures

C<< my @relatedList = $sprout->RelatedFeatures($featureID, $function, $userID); >>

Return a list of the features which are bi-directional best hits of the specified feature and
have been assigned the specified function by the specified user. If no such features exists,
an empty list will be returned.

=over 4

=item featureID

ID of the feature to whom the desired features are related.

=item function

Functional assignment (as returned by C</FunctionOf>) that is used to determine which related
features should be selected.

=item userID

ID of the user whose functional assignments are to be used. If omitted, C<FIG> is assumed.

=item RETURN

Returns a list of the related features with the specified function.

=back

=cut
#: Return Type @;
sub RelatedFeatures {
    # Get the parameters.
    my ($self, $featureID, $function, $userID) = @_;
    # Get a list of the features that are BBHs of the incoming feature.
    my @bbhFeatures = map { $_->[0] } FIGRules::BBHData($featureID);
    # Now we loop through the features, pulling out the ones that have the correct
    # functional assignment.
    my @retVal = ();
    for my $bbhFeature (@bbhFeatures) {
        # Get this feature's functional assignment.
        my $newFunction = $self->FunctionOf($bbhFeature, $userID);
        # If it matches, add it to the result list.
        if ($newFunction eq $function) {
            push @retVal, $bbhFeature;
        }
    }
    # Return the result list.
    return @retVal;
}

=head3 TaxonomySort

C<< my @sortedFeatureIDs = $sprout->TaxonomySort(\@featureIDs); >>

Return a list formed by sorting the specified features by the taxonomy of the containing
genome. This will cause genomes from similar organisms to float close to each other.

This task could almost be handled by the database; however, the taxonomy string in the
database is a text field and can't be indexed. Instead, we create a hash table that maps
taxonomy strings to lists of features. We then process the hash table using a key sort
and merge the feature lists together to create the output.

=over 4

=item $featureIDs

List of features to be taxonomically sorted.

=item RETURN

Returns the list of features sorted by the taxonomies of the containing genomes.

=back

=cut
#: Return Type @;
sub TaxonomySort {
    # Get the parameters.
    my ($self, $featureIDs) = @_;
    # Create the working hash table.
    my %hashBuffer = ();
    # Loop through the features.
    for my $fid (@{$featureIDs}) {
        # Get the taxonomy of the feature's genome.
        my ($taxonomy) = $self->GetFlat(['IsLocatedIn', 'HasContig', 'Genome'], "IsLocatedIn(from-link) = ?",
                                        [$fid], 'Genome(taxonomy)');
        # Add this feature to the hash buffer.
        Tracer::AddToListMap(\%hashBuffer, $taxonomy, $fid);
    }
    # Sort the keys and get the elements.
    my @retVal = ();
    for my $taxon (sort keys %hashBuffer) {
        push @retVal, @{$hashBuffer{$taxon}};
    }
    # Return the result.
    return @retVal;
}

=head3 Protein

C<< my $protein = Sprout::Protein($sequence, $table); >>

Translate a DNA sequence into a protein sequence.

=over 4

=item sequence

DNA sequence to translate.

=item table (optional)

Reference to a Hash that translates DNA triples to proteins. A triple that does not
appear in the hash will be translated automatically to C<X>.

=item RETURN

Returns the protein sequence that would be created by the DNA sequence.

=back

=cut

# This is the translation table for protein synthesis.
my $ProteinTable = { AAA => 'K', AAG => 'K', AAT => 'N', AAC => 'N',
                     AGA => 'R', AGG => 'R', AGT => 'S', AGC => 'S',
                     ATA => 'I', ATG => 'M', ATT => 'I', ATC => 'I',
                     ACA => 'T', ACG => 'T', ACT => 'T', ACC => 'T',
                     GAA => 'E', GAG => 'E', GAT => 'D', GAC => 'D',
                     GTA => 'V', GTG => 'V', GTT => 'V', GTC => 'V',
                     GGA => 'G', GGG => 'G', GGT => 'G', GGC => 'G',
                     GCA => 'A', GCG => 'A', GCT => 'A', GCC => 'A',
                     CAA => 'Q', CAG => 'Q', CAT => 'H', CAC => 'H',
                     CTA => 'L', CTG => 'L', CTT => 'L', CTC => 'L',
                     CGA => 'R', CGG => 'R', CGT => 'R', CGC => 'R',
                     CCA => 'P', CCG => 'P', CCT => 'P', CCC => 'P',
                     TAA => '*', TAG => '*', TAT => 'Y', TAC => 'Y',
                     TGA => '*', TGG => 'W', TGT => 'C', TGC => 'C',
                     TTA => 'L', TTG => 'L', TTT => 'F', TTC => 'F',
                     TCA => 'S', TCG => 'S', TCT => 'S', TCC => 'S',
                     AAR => 'K', AAY => 'N',
                     AGR => 'R', AGY => 'S',
                     ATY => 'I',
                     ACR => 'T', ACY => 'T', 'ACX' => 'T',
                     GAR => 'E', GAY => 'D',
                     GTR => 'V', GTY => 'V', GTX => 'V',
                     GGR => 'G', GGY => 'G', GGX => 'G',
                     GCR => 'A', GCY => 'A', GCX => 'A',
                     CAR => 'Q', CAY => 'H',
                     CTR => 'L', CTY => 'L', CTX => 'L',
                     CGR => 'R', CGY => 'R', CGX => 'R',
                     CCR => 'P', CCY => 'P', CCX => 'P',
                     TAR => '*', TAY => 'Y',
                     TGY => 'C',
                     TTR => 'L', TTY => 'F',
                     TCR => 'S', TCY => 'S', TCX => 'S'
                   };

sub Protein {
    # Get the paraeters.
    my ($sequence, $table) = @_;
    # If no table was specified, use the default.
    if (!$table) {
        $table = $ProteinTable;
    }
    # Create the return value.
    my $retVal = "";
    # Loop through the input triples.
    my $n = length $sequence;
    for (my $i = 0; $i < $n; $i += 3) {
        # Get the current triple from the sequence.
        my $triple = substr($sequence, $i, 3);
        # Translate it using the table.
        my $protein = "X";
        if (exists $table->{$triple}) { $protein = $table->{$triple}; }
        $retVal .= $protein;
    }
    # Remove the stop codon (if any).
    $retVal =~ s/\*$//;
    # Return the result.
    return $retVal;
}

=head3 LoadInfo

C<< my ($dirName, @relNames) = $sprout->LoadInfo(); >>

Return the name of the directory from which data is to be loaded and a list of the relation
names. This information is useful when trying to analyze what needs to be put where in order
to load the entire database.

=cut
#: Return Type @;
sub LoadInfo {
    # Get the parameters.
    my ($self) = @_;
    # Create the return list, priming it with the name of the data directory.
    my @retVal = ($self->{_options}->{dataDir});
    # Concatenate the table names.
    push @retVal, $self->GetTableNames();
    # Return the result.
    return @retVal;
}

=head3 LowBBHs

C<< my %bbhMap = $sprout->LowBBHs($featureID, $cutoff); >>

Return the bidirectional best hits of a feature whose score is no greater than a
specified cutoff value. A higher cutoff value will allow inclusion of hits with
a greater score. The value returned is a map of feature IDs to scores.

=over 4

=item featureID

ID of the feature whose best hits are desired.

=item cutoff

Maximum permissible score for inclusion in the results.

=item RETURN

Returns a hash mapping feature IDs to scores.

=back

=cut
#: Return Type %;
sub LowBBHs {
    # Get the parsameters.
    my ($self, $featureID, $cutoff) = @_;
    # Create the return hash.
    my %retVal = ();
    # Query for the desired BBHs.
    my @bbhList = FIGRules::BBHData($featureID, $cutoff);
    # Form the results into the return hash.
    for my $pair (@bbhList) {
        $retVal{$pair->[0]} = $pair->[1];
    }
    # Return the result.
    return %retVal;
}

=head3 Sims

C<< my $simList = $sprout->Sims($fid, $maxN, $maxP, $select, $max_expand, $filters); >>

Get a list of similarities for a specified feature. Similarity information is not kept in the
Sprout database; rather, they are retrieved from a network server. The similarities are
returned as B<Sim> objects. A Sim object is actually a list reference that has been blessed
so that its elements can be accessed by name.

Similarities can be either raw or expanded. The raw similarities are basic
hits between features with similar DNA. Expanding a raw similarity drags in any
features considered substantially identical. So, for example, if features B<A1>,
B<A2>, and B<A3> are all substatially identical to B<A>, then a raw similarity
B<[C,A]> would be expanded to B<[C,A] [C,A1] [C,A2] [C,A3]>.

=over 4

=item fid

ID of the feature whose similarities are desired.

=item maxN

Maximum number of similarities to return.

=item maxP

Minumum allowable similarity score.

=item select

Selection criterion: C<raw> means only raw similarities are returned; C<fig>
means only similarities to FIG features are returned; C<all> means all expanded
similarities are returned; and C<figx> means similarities are expanded until the
number of FIG features equals the maximum.

=item max_expand

The maximum number of features to expand.

=item filters

Reference to a hash containing filter information, or a subroutine that can be
used to filter the sims.

=item RETURN

Returns a reference to a list of similarity objects, or C<undef> if an error
occurred.

=back

=cut

sub Sims {
    # Get the parameters.
    my ($self, $fid, $maxN, $maxP, $select, $max_expand, $filters) = @_;
    # Create the shim object to test for deleted FIDs.
    my $shim = FidCheck->new($self);
    # Ask the network for sims.
    my $retVal = FIGRules::GetNetworkSims($shim, $fid, {}, $maxN, $maxP, $select, $max_expand, $filters);
    # Return the result.
    return $retVal;
}

=head3 GetGroups

C<< my %groups = $sprout->GetGroups(\@groupList); >>

Return a hash mapping each group to the IDs of the genomes in the group.
A list of groups may be specified, in which case only those groups will be
shown. Alternatively, if no parameter is supplied, all groups will be
included. Genomes that are not in any group are omitted.

=cut
#: Return Type %@;
sub GetGroups {
    # Get the parameters.
    my ($self, $groupList) = @_;
    # Declare the return value.
    my %retVal = ();
    # Determine whether we are getting all the groups or just some.
    if (defined $groupList) {
        # Here we have a group list. Loop through them individually,
        # getting a list of the relevant genomes.
        for my $group (@{$groupList}) {
            my @genomeIDs = $self->GetFlat(['Genome'], "Genome(primary-group) = ?",
                [$group], "Genome(id)");
            $retVal{$group} = \@genomeIDs;
        }
    } else {
        # Here we need all of the groups. In this case, we run through all
        # of the genome records, putting each one found into the appropriate
        # group. Note that we use a filter clause to insure that only genomes
        # in real NMPDR groups are included in the return set.
        my @genomes = $self->GetAll(['Genome'], "Genome(primary-group) <> ?",
                                    [$FIG_Config::otherGroup], ['Genome(id)', 'Genome(primary-group)']);
        # Loop through the genomes found.
        for my $genome (@genomes) {
            # Pop this genome's ID off the current list.
            my @groups = @{$genome};
            my $genomeID = shift @groups;
            # Loop through the groups, adding the genome ID to each group's
            # list.
            for my $group (@groups) {
                Tracer::AddToListMap(\%retVal, $group, $genomeID);
            }
        }
    }
    # Return the hash we just built.
    return %retVal;
}

=head3 MyGenomes

C<< my @genomes = Sprout::MyGenomes($dataDir); >>

Return a list of the genomes to be included in the Sprout.

This method is provided for use during the Sprout load. It presumes the Genome load file has
already been created. (It will be in the Sprout data directory and called either C<Genome>
or C<Genome.dtx>.) Essentially, it reads in the Genome load file and strips out the genome
IDs.

=over 4

=item dataDir

Directory containing the Sprout load files.

=back

=cut
#: Return Type @;
sub MyGenomes {
    # Get the parameters.
    my ($dataDir) = @_;
    # Compute the genome file name.
    my $genomeFileName = LoadFileName($dataDir, "Genome");
    # Extract the genome IDs from the files.
    my @retVal = map { $_ =~ /^(\S+)/; $1 } Tracer::GetFile($genomeFileName);
    # Return the result.
    return @retVal;
}

=head3 LoadFileName

C<< my $fileName = Sprout::LoadFileName($dataDir, $tableName); >>

Return the name of the load file for the specified table in the specified data
directory.

=over 4

=item dataDir

Directory containing the Sprout load files.

=item tableName

Name of the table whose load file is desired.

=item RETURN

Returns the name of the file containing the load data for the specified table, or
C<undef> if no load file is present.

=back

=cut
#: Return Type $;
sub LoadFileName {
    # Get the parameters.
    my ($dataDir, $tableName) = @_;
    # Declare the return variable.
    my $retVal;
    # Check for the various file names.
    if (-e "$dataDir/$tableName") {
        $retVal = "$dataDir/$tableName";
    } elsif (-e "$dataDir/$tableName.dtx") {
        $retVal = "$dataDir/$tableName.dtx";
    }
    # Return the result.
    return $retVal;
}

=head3 DeleteGenome

C<< my $stats = $sprout->DeleteGenome($genomeID, $testFlag); >>

Delete a genome from the database.

=over 4

=item genomeID

ID of the genome to delete

=item testFlag

If TRUE, then the DELETE statements will be traced, but no deletions will occur.

=item RETURN

Returns a statistics object describing the rows deleted.

=back

=cut
#: Return Type $%;
sub DeleteGenome {
    # Get the parameters.
    my ($self, $genomeID, $testFlag) = @_;
    # Perform the delete for the genome's features.
    my $retVal = $self->Delete('Feature', "fig|$genomeID.%", $testFlag);
    # Perform the delete for the primary genome data.
    my $stats = $self->Delete('Genome', $genomeID, $testFlag);
    $retVal->Accumulate($stats);
    # Return the result.
    return $retVal;
}

=head3 Fix

C<< my %fixedHash = Sprout::Fix(%groupHash); >>

Prepare a genome group hash (like that returned by L</GetGroups> for processing.
Groups with the same primary name will be combined. The primary name is the
first capitalized word in the group name.

=over 4

=item groupHash

Hash to be fixed up.

=item RETURN

Returns a fixed-up version of the hash.

=back

=cut

sub Fix {
    # Get the parameters.
    my (%groupHash) = @_;
    # Create the result hash.
    my %retVal = ();
    # Copy over the genomes.
    for my $groupID (keys %groupHash) {
        # Make a safety copy of the group ID.
        my $realGroupID = $groupID;
        # Yank the primary name.
        if ($groupID =~ /([A-Z]\w+)/) {
            $realGroupID = $1;
        }
        # Append this group's genomes into the result hash.
        Tracer::AddToListMap(\%retVal, $realGroupID, @{$groupHash{$groupID}});
    }
    # Return the result hash.
    return %retVal;
}

=head3 GroupPageName

C<< my $name = $sprout->GroupPageName($group); >>

Return the name of the page for the specified NMPDR group.

=over 4

=item group

Name of the relevant group.

=item RETURN

Returns the relative page name (e.g. C<../content/campy.php>). If the group file is not in
memory it will be read in.

=back

=cut

sub GroupPageName {
    # Get the parameters.
    my ($self, $group) = @_;
    # Declare the return variable.
    my $retVal;
    # Check for the group file data.
    if (! defined $self->{groupHash}) {
        # Read the group file.
        my %groupData = Sprout::ReadGroupFile($self->{_options}->{dataDir} . "/groups.tbl");
        # Store it in our object.
        $self->{groupHash} = \%groupData;
    }
    # Compute the real group name.
    my $realGroup = $group;
    if ($group =~ /([A-Z]\w+)/) {
        $realGroup = $1;
    }
    # Return the page name.
    $retVal = "../content/" . $self->{groupHash}->{$realGroup}->[1];
    # Return the result.
    return $retVal;
}

=head3 ReadGroupFile

C<< my %groupData = Sprout::ReadGroupFile($groupFileName); >>

Read in the data from the specified group file. The group file contains information
about each of the NMPDR groups.

=over 4

=item name

Name of the group.

=item page

Name of the group's page on the web site (e.g. C<campy.php> for
Campylobacter)

=item genus

Genus of the group

=item species

Species of the group, or an empty string if the group is for an entire
genus. If the group contains more than one species, the species names
should be separated by commas.

=back

The parameters to this method are as follows

=over 4

=item groupFile

Name of the file containing the group data.

=item RETURN

Returns a hash keyed on group name. The value of each hash 

=back

=cut

sub ReadGroupFile {
    # Get the parameters.
    my ($groupFileName) = @_;
    # Declare the return variable.
    my %retVal;
    # Read the group file.
    my @groupLines = Tracer::GetFile($groupFileName);
    for my $groupLine (@groupLines) {
        my ($name, $page, $genus, $species) = split(/\t/, $groupLine);
        $retVal{$name} = [$page, $genus, $species];
    }
    # Return the result.
    return %retVal;
}

=head2 Internal Utility Methods

=head3 ParseAssignment

Parse annotation text to determine whether or not it is a functional assignment. If it is,
the user, function text, and assigning user will be returned as a 3-element list. If it
isn't, an empty list will be returned.

A functional assignment is always of the form

    C<set >I<YYYY>C< function to\n>I<ZZZZZ>

where I<YYYY> is the B<user>, and I<ZZZZ> is the actual functional role. In most cases,
the user and the assigning user (from MadeAnnotation) will be the same, but that is
not always the case.

In addition, the functional role may contain extra data that is stripped, such as
terminating spaces or a comment separated from the rest of the text by a tab.

This is a static method.

=over 4

=item user

Name of the assigning user.

=item text

Text of the annotation.

=item RETURN

Returns an empty list if the annotation is not a functional assignment; otherwise, returns
a two-element list containing the user name and the function text.

=back

=cut

sub _ParseAssignment {
    # Get the parameters.
    my ($user, $text) = @_;
    # Declare the return value.
    my @retVal = ();
    # Check to see if this is a functional assignment.
    my ($type, $function) = split(/\n/, $text);
    if ($type =~ m/^set function to$/i) {
        # Here we have an assignment without a user, so we use the incoming user ID.
        @retVal = ($user, $function);
    } elsif ($type =~ m/^set (\S+) function to$/i) {
        # Here we have an assignment with a user that is passed back to the caller.
        @retVal = ($1, $function);
    }
    # If we have an assignment, we need to clean the function text. There may be
    # extra junk at the end added as a note from the user.
    if (defined( $retVal[1] )) {
        $retVal[1] =~ s/(\t\S)?\s*$//;
    }
    # Return the result list.
    return @retVal;
}

=head3 FriendlyTimestamp

Convert a time number to a user-friendly time stamp for display.

This is a static method.

=over 4

=item timeValue

Numeric time value.

=item RETURN

Returns a string containing the same time in user-readable format.

=back

=cut

sub FriendlyTimestamp {
    my ($timeValue) = @_;
    my $retVal = localtime($timeValue);
    return $retVal;
}

=head3 AddProperty

C<< my  = $sprout->AddProperty($featureID, $key, $value, $url); >>

Add a new attribute value (Property) to a feature. In the SEED system, attributes can
be added to almost any object. In Sprout, they can only be added to features. In
Sprout, attributes are implemented using I<properties>. A property represents a key/value
pair. If the particular key/value pair coming in is not already in the database, a new
B<Property> record is created to hold it.

=over 4

=item peg

ID of the feature to which the attribute is to be replied.

=item key

Name of the attribute (key).

=item value

Value of the attribute.

=item url

URL or text citation from which the property was obtained.

=back

=cut
#: Return Type ;
sub AddProperty {
    # Get the parameters.
    my ($self, $featureID, $key, $value, $url) = @_;
    # Declare the variable to hold the desired property ID.
    my $propID;
    # Attempt to find a property record for this key/value pair.
    my @properties = $self->GetFlat(['Property'],
                                   "Property(property-name) = ? AND Property(property-value) = ?",
                                   [$key, $value], 'Property(id)');
    if (@properties) {
        # Here the property is already in the database. We save its ID.
        $propID = $properties[0];
        # Here the property value does not exist. We need to generate an ID. It will be set
        # to a number one greater than the maximum value in the database. This call to
        # GetAll will stop after one record.
        my @maxProperty = $self->GetAll(['Property'], "ORDER BY Property(id) DESC", [], ['Property(id)'],
                                        1);
        $propID = $maxProperty[0]->[0] + 1;
        # Insert the new property value.
        $self->Insert('Property', { 'property-name' => $key, 'property-value' => $value, id => $propID });
    }
    # Now we connect the incoming feature to the property.
    $self->Insert('HasProperty', { 'from-link' => $featureID, 'to-link' => $propID, evidence => $url });
}


1;

MCS Webmaster
ViewVC Help
Powered by ViewVC 1.0.3