[Bio] / Sprout / NmpdrFix.pl Repository:
ViewVC logotype

View of /Sprout/NmpdrFix.pl

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (download) (as text) (annotate)
Mon Jan 19 21:57:23 2009 UTC (10 years, 10 months ago) by parrello
Branch: MAIN
CVS Tags: mgrast_dev_08112011, mgrast_dev_08022011, rast_rel_2014_0912, mgrast_dev_04082011, rast_rel_2010_0928, mgrast_version_3_2, mgrast_dev_12152011, mgrast_dev_06072011, rast_rel_2009_0925, rast_rel_2010_0526, rast_rel_2014_0729, rast_rel_2009_05_18, rast_rel_2010_1206, mgrast_release_3_0, mgrast_dev_03252011, rast_rel_2010_0118, rast_rel_2009_02_05, rast_rel_2011_0119, mgrast_release_3_0_4, mgrast_release_3_0_2, mgrast_release_3_0_3, mgrast_release_3_0_1, mgrast_dev_03312011, mgrast_release_3_1_2, mgrast_release_3_1_1, mgrast_release_3_1_0, mgrast_dev_04132011, mgrast_dev_04012011, rast_rel_2009_07_09, rast_rel_2010_0827, myrast_33, rast_rel_2011_0928, mgrast_dev_04052011, rast_rel_2009_03_26, mgrast_dev_10262011, HEAD
Changes since 1.1: +18 -0 lines
Improved site maintenance utilities.

#!/usr/bin/perl -w

#
# Copyright (c) 2003-2006 University of Chicago and Fellowship
# for Interpretations of Genomes. All Rights Reserved.
#
# This file is part of the SEED Toolkit.
#
# The SEED Toolkit is free software. You can redistribute
# it and/or modify it under the terms of the SEED Toolkit
# Public License.
#
# You should have received a copy of the SEED Toolkit Public License
# along with this program; if not write to the University of Chicago
# at info@ci.uchicago.edu or the Fellowship for Interpretation of
# Genomes at veronika@thefig.info or download a copy from
# http://www.theseed.org/LICENSE.TXT.
#

use strict;
use Tracer;
use DocUtils;

=head1 NmpdrFix Script

=head2 Introduction

This script makes small changes to the NMPDR configuration. It is used in
several standard operating procedures.

=head2 Command-Line Options

=over 4

=item trace

Specifies the tracing level. The higher the tracing level, the more messages
will appear in the trace log. Use E to specify emergency tracing.

=item ff

If specified, the new release number for FigFams. The NMPDR will be pointed to
the specified release.

=item sectionTest

If specified, a comma-delimited list of genome IDs to be used for testing
the Sprout loader. A C<sections.tbl> file will be created using the specified
genome IDs.

=item user

Name suffix to be used for log files. If omitted, the PID is used.

=item sql

If specified, turns on tracing of SQL activity.

=item background

Save the standard and error output to files. The files will be created
in the FIG temporary directory and will be named C<err>I<User>C<.log> and
C<out>I<User>C<.log>, respectively, where I<User> is the value of the
B<user> option above.

=item help

Display this command's parameters and options.

=item warn

Create an event in the RSS feed when an error occurs.

=item phone

Phone number to message when the script is complete.

=back

=cut

# Get the command-line options and parameters.
my ($options, @parameters) = StandardSetup([qw(DocUtils) ],
                                           {
                                              trace => ["2", "tracing level"],
                                              sectionTest => ["", "comma-delimited list of genomes for load testing"],
                                              ff => ["", "new figfam release number"],
                                              phone => ["", "phone number (international format) to call when load finishes"]
                                           },
                                           "",
                                           @ARGV);
# Set a variable to contain return type information.
my $rtype;
# Insure we catch errors.
eval {
    # Check the options.
    if ($options->{ff}) {
        # Here there's a new FIGfams release.
        my $release = $options->{ff};
        # Compute the new FIGfams directory name.
        my $ffDir = "/disks/nmpdr/figfams/Release$release/FigfamsData.Release.$release";
        # Insure it exists.
        if (! -d $ffDir) {
            Trace("Error: FIGfams release $release is unavailable or in the wrong directory.") if T(0);
        } else {
            # It does, so stash it in the FIG_Config.
            my $config_file = "$FIG_Config::fig_disk/config/FIG_Config.pm";
            Trace("Updating $config_file for FIGfams release $release.") if T(2);
            DocUtils::ModifyConfigFile($config_file, { FigfamsData => $ffDir }, []);
        }
    }
    if ($options->{sectionTest}) {
        # Here we need to create the sections.tbl file.
        my $sectionFile = "$FIG_Config::sproutData/sections.tbl";
        my $oh = Open(undef, ">$sectionFile");
        # Get the genome IDs to put in it.
        my @genomes = split /\s*,\s*/, $options->{sectionTest};
        Trace(scalar(@genomes) . " found for load test: " . join(", ", @genomes)) if T(3);
        print $oh join("\n", @genomes, "Globals");
        close $oh;
        Trace("Test file \"$sectionFile\" created.") if T(2);
    }
};
if ($@) {
    Trace("Script failed with error: $@") if T(0);
    $rtype = "error";
} else {
    Trace("Script complete.") if T(2);
    $rtype = "no error";
}
if ($options->{phone}) {
    my $msgID = Tracer::SendSMS($options->{phone}, "NmpdrFix terminated with $rtype.");
    if ($msgID) {
        Trace("Phone message sent with ID $msgID.") if T(2);
    } else {
        Trace("Phone message not sent.") if T(2);
    }
}

1;

MCS Webmaster
ViewVC Help
Powered by ViewVC 1.0.3