View of /Sprout/CleanUp.pl

#!/usr/bin/perl -w

#
# Copyright (c) 2003-2006 University of Chicago and Fellowship
# for Interpretations of Genomes. All Rights Reserved.
#
# This file is part of the SEED Toolkit.
#
# The SEED Toolkit is free software. You can redistribute
# it and/or modify it under the terms of the SEED Toolkit
# Public License.
#
# You should have received a copy of the SEED Toolkit Public License
# along with this program; if not write to the University of Chicago
# at info@ci.uchicago.edu or the Fellowship for Interpretation of
# Genomes at veronika@thefig.info or download a copy from
# http://www.theseed.org/LICENSE.TXT.
#

use strict;
use Tracer;
use File::stat;
use Stats;


=head1 CleanUp Script

    CleanUp [options] 

Delete old temporary files

=head2 Introduction

This is a simple script that deletes old files from the temporary directories
used by the NMPDR.

=head2 Command-Line Options

=over 4

=item trace

Specifies the tracing level. The higher the tracing level, the more messages
will appear in the trace log. Use E to specify emergency tracing.

=item age

Minimum file age for deletion, in hours. Files that have not been modified in
the specified number of hours will be deleted.

=item sandbox

Path to the SEED/NMPDR sandbox (FIGdisk) to delete. The default is the current
instance.

=item user

Name suffix to be used for log files. If omitted, the PID is used.

=item sql

If specified, turns on tracing of SQL activity.

=item background

Save the standard and error output to files. The files will be created
in the FIG temporary directory and will be named C<err>I<User>C<.log> and
C<out>I<User>C<.log>, respectively, where I<User> is the value of the
B<user> option above.

=item help

Display this command's parameters and options.

=item warn

Create an event in the RSS feed when an error occurs.

=item phone

Phone number to message when the script is complete.

=back

=cut

# Get the command-line options and parameters.
my ($options, @parameters) = StandardSetup([qw() ],
                                           {
                                              trace => [2, "tracing level"],
                                              age => [24, "minimum age in hours for files to be deleted"],
                                              sandbox => ["$FIG_Config::fig_disk", "sandbox whose temp files are to be deleted"],
                                              phone => ["", "phone number (international format) to call when load finishes"]
                                           },
                                           "",
                                           @ARGV);
# Set a variable to contain return type information.
my $rtype;
# Insure we catch errors.
eval {
    # Create a statistics object.
    my $stats = Stats->new(qw(deleted directories locked processed bytes));
    # Get the specified sandbox.
    my $root = $options->{sandbox};
    if (! -d $root) {
        Trace("NMPDR/SEED instance \"$root\" not found.") if T(2);
    } else {
        # Compute the names of the directories to clean.
        my @dirs = ("$root/FIG/Tmp", "$root/FIG/WikiData/working/tmp");
        # We're going to be doing recursive stuff, so we will treat the directory list
        # as a stack.
        while (my $dir = pop @dirs) {
            # Check for the directory.
            if (! -d $dir) {
                # Not found, so just skip it.
                Trace("Directory \"$dir\" does not exist and will be skipped.") if T(2);
            } else {
                # Open it for reading. We don't dare slurp it, because some of these
                # directories contain millions of files.
                my $okFlag = opendir(my $dh, $dir);
                if (! $okFlag) {
                    Trace("Could not open \"$dir\": $!") if T(1);
                } else {
                    $stats->Add(directories => 1);
                    Trace("Processing $dir.") if T(2);
                    # Loop through the directory files.
                    while (my $fileTitle = readdir $dh) {
                        # Only process if this is not a dot-marked file.
                        if (substr($fileTitle, 0, 1) ne ".") {
                            # Compute the absolute file name.
                            my $fileName = "$dir/$fileTitle";
                            # Is it a subdirectory?
                            if (-d $fileName) {
                                # Yes, stack it.
                                push @dirs, $fileName;
                            } else {
                                # No, so we have a real file.
                                $stats->Add(processed => 1);
                                my $fileData = stat $fileName;
                                # Check its age.
                                my $age = (time() - $fileData->mtime) / 3600;
                                if ($age >= $options->{age}) {
                                    # It's old, so we want to delete it. Get its size
                                    # first, so we can track the bytes saved.
                                    my $byteSize = $fileData->blksize * $fileData->blocks;
                                    eval { $okFlag = unlink($fileName); };
                                    if ($@) {
                                        Trace("Error deleting $fileName: $@") if T(3);
                                        $stats->Add(locked => 1);
                                    } elsif (! $okFlag) {
                                        # It failed, so count it as a lock.
                                        $stats->Add(locked => 1);
                                    } else {
                                        # It worked, so count it.
                                        $stats->Add(bytes => $byteSize);
                                        Trace($stats->Ask('bytes') . " bytes and " . $stats->Ask('deleted') . " files deleted.") if $stats->Check(deleted => 1000) && T(3);
                                    }
                                }
                            }
                        }
                    }
                }
            }
        }
        # We're done.
        Trace("Cleanup complete:\n" . $stats->Show()) if T(2);
    }
};
if ($@) {
    Trace("Script failed with error: $@") if T(0);
    $rtype = "error";
} else {
    Trace("Script complete.") if T(2);
    $rtype = "no error";
}
if ($options->{phone}) {
    my $msgID = Tracer::SendSMS($options->{phone}, "CleanUp terminated with $rtype.");
    if ($msgID) {
        Trace("Phone message sent with ID $msgID.") if T(2);
    } else {
        Trace("Phone message not sent.") if T(2);
    }
}

1;