[Bio] / FigWebServices / genome_feature_dna.cgi Repository:
ViewVC logotype

View of /FigWebServices/genome_feature_dna.cgi

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (download) (annotate)
Sat Jun 28 01:54:05 2008 UTC (11 years, 4 months ago) by golsen
Branch: MAIN
CVS Tags: mgrast_dev_08112011, rast_rel_2009_05_18, mgrast_dev_08022011, rast_rel_2014_0912, myrast_rel40, mgrast_dev_05262011, rast_rel_2008_12_18, mgrast_dev_04082011, rast_rel_2010_0928, rast_2008_0924, mgrast_version_3_2, mgrast_dev_12152011, mgrast_dev_06072011, rast_rel_2008_09_30, rast_rel_2009_0925, rast_rel_2010_0526, rast_rel_2014_0729, mgrast_dev_02212011, rast_rel_2010_1206, mgrast_release_3_0, mgrast_dev_03252011, rast_rel_2010_0118, mgrast_rel_2008_0924, mgrast_rel_2008_1110_v2, rast_rel_2009_02_05, rast_rel_2011_0119, mgrast_rel_2008_0625, mgrast_release_3_0_4, mgrast_release_3_0_2, mgrast_release_3_0_3, mgrast_release_3_0_1, mgrast_dev_03312011, mgrast_release_3_1_2, mgrast_release_3_1_1, mgrast_release_3_1_0, mgrast_dev_04132011, rast_rel_2008_10_09, mgrast_dev_04012011, rast_release_2008_09_29, mgrast_rel_2008_0806, mgrast_rel_2008_0923, mgrast_rel_2008_0919, rast_rel_2009_07_09, rast_rel_2010_0827, mgrast_rel_2008_1110, myrast_33, rast_rel_2011_0928, rast_rel_2008_09_29, mgrast_rel_2008_0917, rast_rel_2008_10_29, mgrast_dev_04052011, mgrast_dev_02222011, rast_rel_2009_03_26, mgrast_dev_10262011, rast_rel_2008_11_24, rast_rel_2008_08_07, HEAD
Add the ability to get DNA sequences for all features of a given type in
a genome.  Results are written to a file (not browser window).

#
# Copyright (c) 2003-2008 University of Chicago and Fellowship
# for Interpretations of Genomes. All Rights Reserved.
#
# This file is part of the SEED Toolkit.
# 
# The SEED Toolkit is free software. You can redistribute
# it and/or modify it under the terms of the SEED Toolkit
# Public License. 
#
# You should have received a copy of the SEED Toolkit Public License
# along with this program; if not write to the University of Chicago
# at info@ci.uchicago.edu or the Fellowship for Interpretation of
# Genomes at veronika@thefig.info or download a copy from
# http://www.theseed.org/LICENSE.TXT.
#

#  Derived from genome_peg_dna.pl.

use strict;

my $usage =<<'End_of_usage';
<PRE>
usage: genome_feature_dna.cgi

required prameter:
    genome    = gid

optional prameters:
   annotate  = boolean       # include annotation on definition lines (D = 0)
   contig    = contig[,contig,...]   # restrict to one or more specific contigs
   deleted   = boolean       # include deleted pegs (D = 0)
   type      = feature_type  # feature type (D = peg)
   uppercase = boolean       # use uppercase charabers (D = lowercase)
</PRE>
End_of_usage

use FIG;
my $fig = new FIG;

use CGI;
my $cgi = new CGI;

use gjoseqlib;

my $gid = $cgi->param('genome');
if ( ! $gid )
{
    report_error( "Sorry, you need to specify a genome id\n$usage" );
}

my $annotate = $cgi->param('annotate')  || 0;
my $deleted  = $cgi->param('deleted')   || 0;
my $type     = $cgi->param('type')      || 'peg';
my $upper    = $cgi->param('uppercase') || $cgi->param('upper') || 0;

my %keep_contig = map { $_ => 1 }
                  map { split /,/ }
                  $cgi->param('contig');
my $filter = ( keys %keep_contig ) > 0;

my $orgdir = "$FIG_Config::organisms/$gid";
-r $orgdir or report_error( "Cannot read organism directory for $gid\n" );

#  This does not handle the few cases of contigs in multiple files:

my $contigfile = "$orgdir/contigs";
-r $contigfile or report_error( "Cannot read contigs file for $gid\n" );

my $tblfile = "$orgdir/Features/$type/tbl";
-r $tblfile or report_error( "Cannot read feature table of type '$type' for $gid\n" );

my %deleted;
if ( ! $deleted )
{
    my $globdir = "$FIG_Config::global";
    -r $globdir or report_error( "Cannot read SEED global directory\n" );

    my $delfile = "$globdir/deleted.features";
    -r $delfile or report_error( "Cannot read deleted features file\n" );

    open DEL, "<$delfile" or report_error( "Could not open deleted features file\n" );
    %deleted = map { chomp; ( $_ => 1 ) } <DEL>;
    close DEL;
}

open( CONTIGS, "<$contigfile" ) or report_error( "Could not open contigs file\n" );
open( TBLFILE, "<$tblfile" )    or report_error( "Could not open feature table of type '$type' for $gid\n" );

#  Read the table file, recording the subsequences to be assembled:

my @fids;
my %seqs;
my %by_contig;

my ( $entry, $fid, $loc, $desc, $org, $func );
my ( $cid, $seq, %contigs, %veto );
while ( defined( $entry = <TBLFILE> ) )
{
    chomp $entry;
    if ( ( ( $fid, $loc ) = $entry =~ /^(\S+)\t(\S+)/ ) && $fid && $loc )
    {
        next if $deleted{ $fid };
        #  @loc = ( [contig,beg,end], ... )
        my @loc = map { [ /^(.*)_(\d+)_(\d+)$/ ] } split /,/, $loc;
        report_error( "Bad location in tbl: $fid $loc\n" ) if grep { ! $_->[0] || ! $_->[1] || ! $_->[2] } @loc;
        my @bad_contig = grep { $filter && ! $keep_contig{ $_->[0] } } @loc;
        next if @bad_contig;

        push @fids, $fid;
        my $seq = [ map { '' } @loc ];  # Place to assemble sequence fragments
        $seqs{ $fid } = $seq;

        my $n = 0;
        foreach ( @loc )
        {
            push @{ $by_contig{ $_->[0] } }, [ $seq, $n++, $_->[1], $_->[2] ];
        }
    }
    elsif ( $entry )
    {
        report_error( "Bad tbl entry: $entry\n" );
    }
}
close( TBLFILE );

#  Read the contigs, grabbing appropriate subsequences and stuffing them
#  into the sequence templates created above:

while ( $entry = gjoseqlib::read_next_fasta_seq( \*CONTIGS ) )
{
	$cid = $entry->[0];
	next if $filter && ! $keep_contig{ $cid };
	foreach ( @{ $by_contig{ $cid } } )
	{
	    my ( $seq, $n, $beg, $end ) = @$_;
	    $seq->[ $n ] = gjoseqlib::DNA_subseq( \$entry->[2], $beg, $end );
    }
}
close( CONTIGS );

#  Contigs have been read; output the sequences:

print <<"End_of_head";
Content-Type: text/plain; charset=ISO-8859-1
Content-Disposition:\tattachment;\tfilename=$gid.dna

End_of_head

foreach $fid ( @fids )
{
    $seq = $upper ? uc join( '', @{ $seqs{ $fid } } )
                  : lc join( '', @{ $seqs{ $fid } } );
    if ( $annotate )
    {
        $org = $fig->org_of( $fid ) or next;
        $func = ( scalar $fig->function_of( $fid ) ) || 'undefined function';
        $desc = "$fid $func [$org]";
    }
    else
    {
        $desc = $fid;
    }
    FIG::display_id_and_seq( $desc, \$seq );
}


sub report_error
{
	my $message = shift;

    print <<"End_of_head";
Content-Type: text/html; charset=ISO-8859-1

<HTML>
<HEAD>
<TITLE>The SEED: genome_feature_dna</TITLE>
</HEAD>
<BODY>
$message
</BODY>
</HTML>
End_of_head

    exit;
}

MCS Webmaster
ViewVC Help
Powered by ViewVC 1.0.3