[Bio] / FigWebServices / AttribXMLRPC.cgi Repository:
ViewVC logotype

View of /FigWebServices/AttribXMLRPC.cgi

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.9 - (download) (annotate)
Fri May 11 06:07:59 2007 UTC (12 years, 9 months ago) by parrello
Branch: MAIN
CVS Tags: mgrast_dev_08112011, rast_rel_2009_05_18, mgrast_dev_08022011, rast_rel_2014_0912, rast_rel_2008_06_18, myrast_rel40, rast_rel_2008_06_16, mgrast_dev_05262011, rast_rel_2008_12_18, mgrast_dev_04082011, rast_rel_2008_07_21, rast_rel_2010_0928, rast_2008_0924, mgrast_version_3_2, mgrast_dev_12152011, rast_rel_2008_04_23, mgrast_dev_06072011, rast_rel_2008_09_30, rast_rel_2009_0925, rast_rel_2010_0526, rast_rel_2014_0729, mgrast_dev_02212011, rast_rel_2010_1206, mgrast_release_3_0, mgrast_dev_03252011, rast_rel_2010_0118, mgrast_rel_2008_0924, mgrast_rel_2008_1110_v2, rast_rel_2009_02_05, rast_rel_2011_0119, mgrast_rel_2008_0625, mgrast_release_3_0_4, mgrast_release_3_0_2, mgrast_release_3_0_3, mgrast_release_3_0_1, mgrast_dev_03312011, mgrast_release_3_1_2, mgrast_release_3_1_1, mgrast_release_3_1_0, mgrast_dev_04132011, rast_rel_2008_10_09, mgrast_dev_04012011, rast_release_2008_09_29, mgrast_rel_2008_0806, mgrast_rel_2008_0923, mgrast_rel_2008_0919, rast_rel_2009_07_09, rast_rel_2010_0827, mgrast_rel_2008_1110, myrast_33, rast_rel_2011_0928, rast_rel_2008_09_29, mgrast_rel_2008_0917, rast_rel_2008_10_29, mgrast_dev_04052011, mgrast_dev_02222011, rast_rel_2009_03_26, mgrast_dev_10262011, rast_rel_2008_11_24, rast_rel_2008_08_07, HEAD
Changes since 1.8: +1 -0 lines
Added support for the new method to get attribute descriptions by group.

#
# Copyright (c) 2003-2006 University of Chicago and Fellowship
# for Interpretations of Genomes. All Rights Reserved.
#
# This file is part of the SEED Toolkit.
# 
# The SEED Toolkit is free software. You can redistribute
# it and/or modify it under the terms of the SEED Toolkit
# Public License. 
#
# You should have received a copy of the SEED Toolkit Public License
# along with this program; if not write to the University of Chicago
# at info@ci.uchicago.edu or the Fellowship for Interpretation of
# Genomes at veronika@thefig.info or download a copy from
# http://www.theseed.org/LICENSE.TXT.
#

use Frontier::RPC2;

use FIG;
use CustomAttributes;
use strict;


package FrontierXMLRPCWrapper;

#
# We'll make a class to hold the fig instance and the
# XMLRPC server instance; this will make it easier to invoke the
# wrapping functions (since each one will need these values).
#


#
# Constructor.
#
sub new
{
    my($class, $attr, $xmlrpc) = @_;

    my $self = {
	attributes => $attr,
	xmlrpc => $xmlrpc,
    };

    return bless $self, $class;
}


#
# Return a value properly coerced to a string for passing
# as an XMLRPC return. Use the string() method on the
# xmlrpc instance variable.
#
sub coerce_to_string
{
    my($self, $value) = @_;

    my $new;
    if (ref($value) eq "ARRAY")
    {
	$new = [];
	for my $v (@$value)
	{
	    push(@$new, $self->coerce_to_string($v));
	}
    }
    elsif (ref($value) eq "HASH")
    {
	$new = {};
	for my $k (keys(%$value))
	{
	    $new->{$k} = $self->coerce_to_string($value->{$k});
	}
    }
    elsif ($value =~ /^(-?(?:\d+(?:\.\d*)?|\.\d+)|([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?)$/)
    {
	$new = $self->{xmlrpc}->string($value);
    }
    else
    {
	$new = $value;
    }
    return $new;
}

#
# Wrap a FIG method that returns a scalar.
#

sub wrap_scalar_return
{
    my($self, $func) = @_;

    #
    # We return a new anonymous subroutine that invokes the
    # routine thru the $fig instance saved in our instance variables.
    #

    return sub {
	my $ret;

	$ret = $self->{attributes}->$func(@_);

	#
	# Coerce to string if we need to.
	#
	
	if (!ref($ret))
	{
	    $ret = $self->coerce_to_string($ret);
	}
	
	return $ret;
    }
}

#
# Wrap a FIG method that returns a list. The list needs to be
# converted into a list reference instead of a plain list.
#

sub wrap_array_return
{
    my($self, $func) = @_;

    #
    # We return a new anonymous subroutine that invokes the
    # routine thru the $fig instance saved in our instance variables.
    #

    return sub {
	my $ret;
	my @func_ret;

	$ret = [];

	#
	# Invoke the function.
	#
	@func_ret = $self->{attributes}->$func(@_);

	#
	# For each value returned, if it isn't a reference (to a list, for instance),
	# coerce it to a string.
	#
	# Push each value to the list we're creating.
	#
	for $_ (@func_ret)
	{
	    push(@$ret, $self->coerce_to_string($_));
	}
	return $ret;
    }
}

#
# back in the main package, finished with class definition.
#

package main;

$| = 1;  # Perl magic to use unbuffered output on standard output

my $xml_rpc_server = Frontier::RPC2->new;

my $attr = CustomAttributes->new();

#
# Create a wrapper-helper object.
#

my $wrapper = new FrontierXMLRPCWrapper($attr, $xml_rpc_server);

#
# Create a list of the methods to be served
#

my $methods = {
    'GetAttributes' => $wrapper->wrap_array_return("GetAttributes"),
    'AddAttribute' => $wrapper->wrap_scalar_return("AddAttribute"),
    'DeleteAttribute' => $wrapper->wrap_scalar_return("DeleteAttribute"),
    'ChangeAttribute' => $wrapper->wrap_scalar_return("ChangeAttribute"),
    'EraseAttribute' => $wrapper->wrap_scalar_return("EraseAttribute"),
    'GetAttributeKeys' => $wrapper->wrap_array_return("GetAttributeKeys"),
    'GetAttributeData' => $wrapper->wrap_array_return("GetAttributeData"),
    'DeleteMatchingAttributes' => $wrapper->wrap_array_return("DeleteMatchingAttributes"),
    'QueryAttributes' => $wrapper->wrap_array_return("QueryAttributes")
};

process_cgi_call($methods);

#==========================================================================
#  CGI Support
#==========================================================================
#  Simple CGI support for Frontier::RPC2. You can copy this into your CGI
#  scripts verbatim, or you can package it into a library.
#  (Based on xmlrpc_cgi.c by Eric Kidd <http://xmlrpc-c.sourceforge.net/>.)

# Process a CGI call.
sub process_cgi_call ($) {
    my ($methods) = @_;

    # Get our CGI request information.
    my $method = $ENV{'REQUEST_METHOD'};
    my $type = $ENV{'CONTENT_TYPE'};
    my $length = $ENV{'CONTENT_LENGTH'};

    # Perform some sanity checks.
    http_error(405, "Method Not Allowed") unless $method eq "POST";
    http_error(400, "Bad Request") unless $type eq "text/xml";
    http_error(411, "Length Required") unless $length > 0;

    # Fetch our body.
    my $body;
    my $count = read STDIN, $body, $length;
    http_error(400, "Bad Request") unless $count == $length; 

    # Serve our request.
    my $coder = Frontier::RPC2->new;
    send_xml($coder->serve($body, $methods));
}

# Send an HTTP error and exit.
sub http_error ($$) {
    my ($code, $message) = @_;
    print <<"EOD";
Status: $code $message
Content-type: text/html

<title>$code $message</title>
<h1>$code $message</h1>
<p>Unexpected error processing XML-RPC request.</p>
EOD
    exit 0;
}

# Send an XML document (but don't exit).
sub send_xml ($) {
    my ($xml_string) = @_;
    my $length = length($xml_string);
    print <<"EOD";
Status: 200 OK
Content-type: text/xml
Content-length: $length

EOD
    # We want precise control over whitespace here.
    print $xml_string;
}

MCS Webmaster
ViewVC Help
Powered by ViewVC 1.0.3