[Bio] / FigKernelScripts / make_parallel_proml_run.pl Repository:
ViewVC logotype

View of /FigKernelScripts/make_parallel_proml_run.pl

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (download) (as text) (annotate)
Sat Jan 13 03:22:44 2007 UTC (13 years, 1 month ago) by overbeek
Branch: MAIN
CVS Tags: mgrast_dev_08112011, rast_rel_2009_05_18, mgrast_dev_08022011, rast_rel_2014_0912, rast_rel_2008_06_18, myrast_rel40, rast_rel_2008_06_16, mgrast_dev_05262011, rast_rel_2008_12_18, mgrast_dev_04082011, rast_rel_2008_07_21, rast_rel_2010_0928, rast_2008_0924, mgrast_version_3_2, mgrast_dev_12152011, rast_rel_2008_04_23, mgrast_dev_06072011, rast_rel_2008_09_30, rast_rel_2009_0925, rast_rel_2010_0526, rast_rel_2014_0729, mgrast_dev_02212011, rast_rel_2010_1206, mgrast_release_3_0, mgrast_dev_03252011, rast_rel_2010_0118, mgrast_rel_2008_0924, mgrast_rel_2008_1110_v2, rast_rel_2009_02_05, rast_rel_2011_0119, mgrast_rel_2008_0625, mgrast_release_3_0_4, mgrast_release_3_0_2, mgrast_release_3_0_3, mgrast_release_3_0_1, mgrast_dev_03312011, mgrast_release_3_1_2, mgrast_release_3_1_1, mgrast_release_3_1_0, mgrast_dev_04132011, rast_rel_2008_10_09, mgrast_dev_04012011, rast_release_2008_09_29, mgrast_rel_2008_0806, mgrast_rel_2008_0923, mgrast_rel_2008_0919, rast_rel_2009_07_09, rast_rel_2010_0827, mgrast_rel_2008_1110, myrast_33, rast_rel_2011_0928, rast_rel_2008_09_29, mgrast_rel_2008_0917, rast_rel_2008_10_29, mgrast_dev_04052011, mgrast_dev_02222011, rast_rel_2009_03_26, mgrast_dev_10262011, rast_rel_2008_11_24, rast_rel_2008_08_07, HEAD
Changes since 1.1: +54 -27 lines
add rates to phylogeny stuff

########
#
# The "grand goal" is to run 'proml' on many different machines using the same alignment
# as input, but adding the sequences to the tree in distinct orders.  Then, we can
# sift through the outputs, find the best tree, and throw the others away.
#
# This is a strange program that generates a program to be run on many other machines.
# It generates a program with an embedded alignment.  When the program is run,
# it will use 'proml' (with the appropriate alpha parameter) to generate a tree.
# The tree and the 'outfile' generated by proml are packaged up as
# 
#     outfile
#     //
#     outtree
#     ///
# 
# and written to stdout.  The generated tree depends on order of addition, which
# is random.  Hence, you can run this on 50 different machines and get 50 distinct
# estimates of the best tree using maximum liklihood.
#
#########

use gjonewicklib;
use gjoseqlib;

$usage = "usage: make_parallel_proml_run [-a alpha] [-w WeightsAndRates] Alignment GeneratedCommand";

my $alpha = 'undef';
my $wr    = undef;
while ($ARGV[0] =~ /^-/)
{
    $_ = shift @ARGV;
    if    ($_ =~ s/^-a//) { $alpha = ($_ || shift @ARGV) }
    elsif ($_ =~ s/^-w//) { $wr    = ($_ || shift @ARGV) }
    else               { die "Bad Flag: $_" }
}

(
 ($aliF    = shift @ARGV) &&
 ($cmdF    = shift @ARGV) && open(CMD,">$cmdF")
)
    || die $usage;

my $cmd = <<'CMD__FILE';
#! /usr/bin/perl

use proml;
use gjoseqlib;
use gjonewicklib;

my   @align  = (
<<ALI>>
);
my $cats = <<CATS>>;
my $wgts = <<WEIGHTS>>;

my @results = proml::proml( \@align,
                          tmp          => '/tmp',
                          tree_format  => 'gjo',
			  alpha        => <<ALPHA>>,
			  n_jumble     => 1,
                          weights      => ($wgts ? $wgts : 0),
                          categories   => ($cats ? $cats : 0),
                       );

print "Ln Likelihood = $results[0]->[1]\n//\n";
&gjonewicklib::writeNewickTree($results[0]->[0]);
print "\n///\n";
CMD__FILE

$cmd =~ s/<<ALPHA>>/$alpha/;

my @ali = gjoseqlib::read_fasta( $aliF );
@ali || die "Could not read alignment from $aliF";
my $ali = join( ",\n", map { "  [ '$_->[0]', '$_->[2]' ]" } @ali );
$cmd =~ s/<<ALI>>/$ali/;

if ( $wr )
{
    open ( WR, "<$wr" ) || die "Could not open weights and rates $wr\n";
    my $n_cat = <WR>;
    chomp $n_cat;
    $_ = <WR>;
    chomp;
    my @rates = split /,?\s+/;
    my $site_rate = <WR>;
    chomp $site_rate;
    my $categories = "[ $n_cat, [ " . join( ', ', @rates ) . " ], '$site_rate' ]";
    $cmd =~ s/<<CATS>>/$categories/s;
    my $site_weight = <WR>;
    chomp $site_weight;
    $cmd =~ s/<<WEIGHTS>>/'$site_weight'/s;
    close( WR );
}
else
{
    $cmd =~ s/<<CATS>>/undef/;
    $cmd =~ s/<<WEIGHTS>>/undef/;
}

print CMD $cmd;
close(CMD);
system "chmod +x $cmdF";

MCS Webmaster
ViewVC Help
Powered by ViewVC 1.0.3