[Bio] / FigKernelScripts / genome_peg_dna.pl Repository:
ViewVC logotype

View of /FigKernelScripts/genome_peg_dna.pl

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.3 - (download) (as text) (annotate)
Fri Nov 2 17:24:05 2007 UTC (12 years ago) by golsen
Branch: MAIN
CVS Tags: mgrast_dev_08112011, rast_rel_2009_05_18, mgrast_dev_08022011, rast_rel_2014_0912, rast_rel_2008_06_18, myrast_rel40, rast_rel_2008_06_16, mgrast_dev_05262011, rast_rel_2008_12_18, mgrast_dev_04082011, rast_rel_2008_07_21, rast_rel_2010_0928, rast_2008_0924, mgrast_version_3_2, mgrast_dev_12152011, rast_rel_2008_04_23, mgrast_dev_06072011, rast_rel_2008_09_30, rast_rel_2009_0925, rast_rel_2010_0526, rast_rel_2014_0729, mgrast_dev_02212011, rast_rel_2010_1206, mgrast_release_3_0, mgrast_dev_03252011, rast_rel_2010_0118, mgrast_rel_2008_0924, mgrast_rel_2008_1110_v2, rast_rel_2009_02_05, rast_rel_2011_0119, mgrast_rel_2008_0625, mgrast_release_3_0_4, mgrast_release_3_0_2, mgrast_release_3_0_3, mgrast_release_3_0_1, mgrast_dev_03312011, mgrast_release_3_1_2, mgrast_release_3_1_1, mgrast_release_3_1_0, mgrast_dev_04132011, rast_rel_2008_10_09, mgrast_dev_04012011, rast_release_2008_09_29, mgrast_rel_2008_0806, mgrast_rel_2008_0923, mgrast_rel_2008_0919, rast_rel_2009_07_09, rast_rel_2010_0827, mgrast_rel_2008_1110, myrast_33, rast_rel_2011_0928, rast_rel_2008_09_29, mgrast_rel_2008_0917, rast_rel_2008_10_29, mgrast_dev_04052011, mgrast_dev_02222011, rast_rel_2009_03_26, mgrast_dev_10262011, rast_rel_2008_11_24, rast_rel_2008_08_07, HEAD
Changes since 1.2: +108 -51 lines
Extensive modifications to allow more options, and handle large genomes
by not reading all the contigs into memory at once.

# -*- perl -*-
#
# Copyright (c) 2003-2006 University of Chicago and Fellowship
# for Interpretations of Genomes. All Rights Reserved.
#
# This file is part of the SEED Toolkit.
# 
# The SEED Toolkit is free software. You can redistribute
# it and/or modify it under the terms of the SEED Toolkit
# Public License. 
#
# You should have received a copy of the SEED Toolkit Public License
# along with this program; if not write to the University of Chicago
# at info@ci.uchicago.edu or the Fellowship for Interpretation of
# Genomes at veronika@thefig.info or download a copy from
# http://www.theseed.org/LICENSE.TXT.
#

#  This version requires ~6 min to do the human genome on a 800 MHz machine
#  with 1.5 GB memory.

my $usage = <<'End_of_Usage';

genome_peg_dna -- Produce a fasta file of peg DNA sequences from a genome,
    optionally restricted to a desired set of contigs.

Usage:  genome_peg_dna [options] genome_id [ contig_id ... ] > fasta

        -a or --annotate    add function and organism to the fasta def lines
        -d or --deleted     omit pegs marked deleted
        -u or --uppercase   uppercase sequences; default is lowercase

For lower level programs, see

    get_dna  contigs_file  tbl_file  > fasta
or
    get_dna  contigs_file  < tbl_file  > fasta
or
    dna_seq  < intervals  > fasta       [ interval = genome_id \t location ]

End_of_Usage

use strict;
use FIG;
use gjoseqlib;
my $fig = new FIG;

my $annotate = 0;
my $deleted  = 0;
my $upper    = 0;
while ( $ARGV[0] =~ /^-/ )
{
    $_ = shift @ARGV;
    if ( s/^-([^-])/$1/ )  # single hyphen; flags can be concatenated
    {
        if ( s/a//g ) { $annotate = 1 }
        if ( s/d//g ) { $deleted  = 1 }
        if ( s/u//g ) { $upper    = 1 }
        if ( $_ ) { print STDERR "Bad flag characters: '$_'\n" and die $usage }
    }
    elsif ( /^--a/ ) { $annotate = 1 }
    elsif ( /^--d/ ) { $deleted  = 1 }
    elsif ( /^--u/ ) { $upper    = 1 }
    else { print STDERR "Bad flag: '$_'\n" and die $usage }
}

my $genome = shift @ARGV or die $usage;

my $filter = @ARGV;
my %keep_contig = map { $_ => 1 } @ARGV;

my $orgdir = "$FIG_Config::organisms/$genome";
-r $orgdir or die "Cannot read organism directory $orgdir\n";

#  This does not handle the few cases of contigs in multiple files:

my $contigfile = "$orgdir/contigs";
-r $contigfile or die "Cannot read contigs file $contigfile\n";

my $tblfile = "$orgdir/Features/peg/tbl";
-r $tblfile or die "Cannot read protein table $tblfile\n";

my %deleted;
if ( $deleted )
{
    my $globdir = "$FIG_Config::global";
    -r $globdir or die "Cannot global directory $globdir\n";

    my $delfile = "$globdir/deleted.features";
    -r $delfile or die "Cannot read deleted features file $delfile\n";

    open DEL, "<$delfile" or die "Could not open deleted features file $delfile\n";
    %deleted = map { chomp; ( $_ => 1 ) } <DEL>;
    close DEL;
}

open( CONTIGS, "<$contigfile" ) or die "Could not open contigs file $contigfile\n";
open( TBLFILE, "<$tblfile" )    or die "Could not open peg tbl file $tblfile\n";

#  Read the table file, recording the subsequences to be assembled:

my @fids;
my %seqs;
my %by_contig;

my ( $entry, $fid, $loc, $desc, $org, $func );
my ( $cid, $seq, %contigs, %veto );
while ( defined( $entry = <TBLFILE> ) )
{
    chomp $entry;
    if ( ( ( $fid, $loc ) = $entry =~ /^(\S+)\t(\S+)/ ) && $fid && $loc )
    {
        next if $deleted{ $fid };
        #  @loc = ( [contig,beg,end], ... )
        my @loc = map { [ /^(.*)_(\d+)_(\d+)$/ ] } split /,/, $loc;
        die "Bad location in tbl: $fid $loc\n" if grep { ! $_->[0] || ! $_->[1] || ! $_->[2] } @loc;
        my @bad_contig = grep { $filter && ! $keep_contig{ $_->[0] } } @loc;
        next if @bad_contig;

        push @fids, $fid;
        my $seq = [ map { '' } @loc ];  # Place to assemble sequence fragments
        $seqs{ $fid } = $seq;

        my $n = 0;
        foreach ( @loc )
        {
            push @{ $by_contig{ $_->[0] } }, [ $seq, $n++, $_->[1], $_->[2] ];
        }
    }
    elsif ( $entry )
    {
        die "Bad tbl entry: $entry\n";
    }
}
close( TBLFILE );

#  Read the contigs, grabbing appropriate subsequences and stuffing them
#  into the sequence templates created above:

while ( $entry = gjoseqlib::read_next_fasta_seq( \*CONTIGS ) )
{
	$cid = $entry->[0];
	next if $filter && ! $keep_contig{ $cid };
	foreach ( @{ $by_contig{ $cid } } )
	{
	    my ( $seq, $n, $beg, $end ) = @$_;
	    $seq->[ $n ] = gjoseqlib::DNA_subseq( \$entry->[2], $beg, $end );
    }
}
close( CONTIGS );

#  Contigs have been read; output the sequences:

foreach $fid ( @fids )
{
    $seq = $upper ? uc join( '', @{ $seqs{ $fid } } )
                  : lc join( '', @{ $seqs{ $fid } } );
    if ( $annotate )
    {
        $org = $fig->org_of( $fid ) or next;
        $func = ( scalar $fig->function_of( $fid ) ) || "hypothetical protein";
        $desc = "$fid $func [$org]";
    }
    else
    {
        $desc = $fid;
    }
    FIG::display_id_and_seq( $desc, \$seq );
}

MCS Webmaster
ViewVC Help
Powered by ViewVC 1.0.3