[Bio] / FigKernelScripts / genbank2gff3.pl Repository:
ViewVC logotype

View of /FigKernelScripts/genbank2gff3.pl

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (download) (as text) (annotate)
Wed Aug 10 15:00:14 2005 UTC (14 years, 10 months ago) by overbeek
Branch: MAIN
Initial release



# A genbank2gff3 converter written by Rob in part for Ed DeLong
# this uses BioPerl to read the genbank file and then writes out a more custom
# gff3 file. 

use strict;
use lib '/Users/Rob/perl/bioperl/cvs/bioperl-live';
use Bio::SeqIO;
use URI::Escape;

# I am not using the Bio::Feature::GFF3 because, well, screw them

my $usage=<<EOF;

$0
-f genbank file
-g genome ID


EOF

my ($file, $genomeid)=('', 'xxxxxxxx');

while (@ARGV) {
 my $t=shift;
 if ($t eq "-f") {$file=shift}
 elsif ($t eq "-g") {$genomeid=shift}
}

die $usage unless ($file);


my $sio=Bio::SeqIO->new(-file=>$file, -format=>"genbank");


my $taxid=$genomeid;
$taxid=~s/\.\d+//;


my $genecount; my $rnacount;
while (my $seqobj=$sio->next_seq) 
{
 print "#gff-version 3\n#seed\tgenome_id\t$genomeid\n#seed\ttaxon_id\t$taxid\n";
 print "#seed\tname\t", $seqobj->desc, "\n";
 print join("\t", "##sequence-region", $seqobj->display_id, "1", $seqobj->length()), "\n";
 
 my %translation;
 foreach my $feature ($seqobj->get_SeqFeatures) {
  #$feat is a Bio::SeqFeature::Generic
  my @gff3;
  my $col9;
  my $id; my $label; 
  if ($feature->primary_tag eq "CDS") 
  {
   $id="fig|".$genomeid.".peg.".++$genecount;
   $label="cds";
   # translate the protein. Here we actually make a new sequence object containing the DNA sequence and then use bioperl to
   # do the translation. There are some things in bioperl that return objects (like translate) and somethings that don't (like subseq)
   # note we also need a rev comp if the strand is -1. If we don't know the strand (or it is not -1) we return the forward translation
   my $translationid="pro.$genecount";
   ($feature->strand == -1) ? 
	($translation{$translationid}=Bio::Seq->new(-seq=>$seqobj->subseq($feature->start, $feature->end))->revcom->translate->seq) :
   	($translation{$translationid}=Bio::Seq->new(-seq=>$seqobj->subseq($feature->start, $feature->end))->translate->seq) ;
  
   push @{$col9->{"translation_id"}}, $translationid;
  }
  elsif ($feature->primary_tag eq "tRNA" || $feature->primary_tag eq "rRNA")
  {
   $id="fig|".$genomeid.".rna.".++$rnacount;
   $label=$feature->primary_tag;
  }
  elsif ($feature->primary_tag eq "gene")
  {
   # we ignore these, especially since they are the same as rna's in this case!
  }
  else {print STDERR "Got a ", $feature->primary_tag, "\n"}
  next unless ($id);
  
  push @gff3, $id;
   
  if ($feature->display_name) {push @{$col9->{"Alias"}}, $feature->display_name}
  if ($feature->source_tag) {push @gff3, $feature->source_tag} else {push @gff3, "DeLong's sequencing"}
  push @gff3, $label, $feature->start, $feature->end;
  $feature->score ? push @gff3, $feature->score : push @gff3, ".";
  $feature->strand == +1 ? push @gff3, "+" : 
    $feature->strand == -1 ? push @gff3, "-" :
     push @gff3, ".";
  $feature->frame ? push @gff3, $feature->frame : push @gff3, ".";
  foreach my $tag ($feature->get_all_tags) {
    push @{$col9->{$tag}}, $feature->get_tag_values($tag)
  }
  
  push @gff3, join(";", map {"$_=" . uri_escape(join(",", @{$col9->{$_}}))} keys %$col9);
  print join("\t", @gff3), "\n";
 }
 # now print out the translations
 print "##FASTA\n";
 map {$translation{$_}=~s/(.{60})/$1\n/g; chomp($translation{$_}); print ">$_\n$translation{$_}\n"} sort keys %translation;
 my $seq=$seqobj->seq;
 $seq=~s/(.{60})/$1\n/g; chomp($seq);
 print ">", $seqobj->display_id, "\n", $seq, "\n";
}





MCS Webmaster
ViewVC Help
Powered by ViewVC 1.0.3