[Bio] / FigKernelScripts / compute_extra_dlit_data.pl Repository:
ViewVC logotype

View of /FigKernelScripts/compute_extra_dlit_data.pl

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.4 - (download) (as text) (annotate)
Sun Jul 13 23:10:59 2008 UTC (11 years, 4 months ago) by golsen
Branch: MAIN
CVS Tags: mgrast_dev_08112011, rast_rel_2009_05_18, mgrast_dev_08022011, rast_rel_2014_0912, myrast_rel40, mgrast_dev_05262011, rast_rel_2008_12_18, mgrast_dev_04082011, rast_rel_2008_07_21, rast_rel_2010_0928, rast_2008_0924, mgrast_version_3_2, mgrast_dev_12152011, mgrast_dev_06072011, rast_rel_2008_09_30, rast_rel_2009_0925, rast_rel_2010_0526, rast_rel_2014_0729, mgrast_dev_02212011, rast_rel_2010_1206, mgrast_release_3_0, mgrast_dev_03252011, rast_rel_2010_0118, mgrast_rel_2008_0924, mgrast_rel_2008_1110_v2, rast_rel_2009_02_05, rast_rel_2011_0119, mgrast_rel_2008_0625, mgrast_release_3_0_4, mgrast_release_3_0_2, mgrast_release_3_0_3, mgrast_release_3_0_1, mgrast_dev_03312011, mgrast_release_3_1_2, mgrast_release_3_1_1, mgrast_release_3_1_0, mgrast_dev_04132011, rast_rel_2008_10_09, mgrast_dev_04012011, rast_release_2008_09_29, mgrast_rel_2008_0806, mgrast_rel_2008_0923, mgrast_rel_2008_0919, rast_rel_2009_07_09, rast_rel_2010_0827, mgrast_rel_2008_1110, myrast_33, rast_rel_2011_0928, rast_rel_2008_09_29, mgrast_rel_2008_0917, rast_rel_2008_10_29, mgrast_dev_04052011, mgrast_dev_02222011, rast_rel_2009_03_26, mgrast_dev_10262011, rast_rel_2008_11_24, rast_rel_2008_08_07, HEAD
Changes since 1.3: +117 -52 lines
Many code clean-ups in the dlits routines, and associated literature.

Add support for indexing the translations in Global/nr.

# -*- perl -*-
########################################################################
# Copyright (c) 2003-2008 University of Chicago and Fellowship
# for Interpretations of Genomes. All Rights Reserved.
#
# This file is part of the SEED Toolkit.
# 
# The SEED Toolkit is free software. You can redistribute
# it and/or modify it under the terms of the SEED Toolkit
# Public License. 
#
# You should have received a copy of the SEED Toolkit Public License
# along with this program; if not write to the University of Chicago
# at info@ci.uchicago.edu or the Fellowship for Interpretation of
# Genomes at veronika@thefig.info or download a copy from
# http://www.theseed.org/LICENSE.TXT.
########################################################################

#  This routine builds the data tables used by load_dlits.  All files are
#  in the directory $FIG_Config::data/Dlits
#
#  First the script merges all PUBMED_CURATED_RELEVANT attributes into the
#  the current dlits and titles database tables.
#
#  It then writes the following files, which are the raw material for
#  reloading the respective database database tables.
#
#  File         Table          Fields
#-------------------------------------------------------------------------------
#  dlits        dlits          status, md5_hash, pubmed, curator, go_code
#  titles       pubmed_titles  pubmed, title
#  curr_role    curr_role      curator, role   # Terrible title: curr means curator
#  hash_role    hash_role      md5_hash, role
#  genome_hash  genome_hash    genome, md5_hash
#-------------------------------------------------------------------------------

use strict;
use FIG;
my $fig = new FIG;

my $Dlits_dir = "$FIG_Config::data/Dlits";
&FIG::verify_dir( $Dlits_dir );

foreach my $x ( $fig->get_attributes( undef, 'PUBMED_CURATED_RELEVANT' ) )
{
    my $peg = $x->[0];
    if ( $x->[2] =~ m/^(master:)?([^,]+),(\d+),(.*)$/i )
    {
        my( $cur, $pubmed, $title ) = ( $2, $3, $4 );

        #  This was duplicating titles.  add_title now tests before adding.

        $fig->add_title( $pubmed, $title );
        my $current_stat = $fig->dlit_status( { -peg => $peg, -pubmed => $pubmed } );
        if ( $current_stat ne 'R' && $current_stat ne 'D' )
        {
            my $rc = $fig->add_dlit( -status   => 'D',
                                     -peg      => $peg,
                                     -pubmed   => $pubmed,
                                     -curator  => $cur,
                                     -override => 1
                                   );
        }
    }
}
$fig->export_dlits();
$fig->export_titles();

#  Find all of the relevant subsystem roles, and curators for them

my %R2C;
foreach my $sub ( $fig->all_subsystems )
{
    my $curator = $fig->subsystem_curator( $sub );
    # print STDERR "$curator: $sub\n";
    next if ! $fig->usable_subsystem( $sub );
    # print STDERR "Is usable\n";

    my @roles = grep { ! $fig->is_aux_role_in_subsystem( $sub, $_ ) }
                $fig->subsystem_to_roles( $sub );

    foreach my $role ( @roles ) { $R2C{ $role }->{ $curator } = 1 }
}

my @pairs;
foreach my $role ( keys %R2C )
{
    push @pairs, map { [ $_, $role ] } keys %{ $R2C{ $role } };
}

open( C2R,">$Dlits_dir/curr_role" )
    || die "could not open $Dlits_dir/curr_role";
foreach ( sort { lc $a->[0] cmp lc $b->[0] || lc $a->[1] cmp lc $b->[1] } @pairs )
{
    print C2R "$_->[0]\t$_->[1]\n";
}
close(C2R);

#  Okay, now we need to map relevant sequences to the roles

open( R2H, ">$Dlits_dir/hash_role" )
    || die "could not open $Dlits_dir/hash_role";
foreach my $role ( keys %R2C )
{
    my %hashes;
    foreach my $peg ( grep { /\.peg\./ && $fig->is_real_feature($_) } $fig->prots_for_role($role) )
    {
        my $hash = $fig->md5_of_peg( $peg );
        if ( $hash ) { $hashes{ $hash } = 1 }
        else         { print STDERR "failed: peg=$peg hash=$hash\n" }
    }
    foreach ( sort keys %hashes ) { print R2H "$_\t$role\n" }
}
close(R2H);

#  Map genomes to sequences with literature attached.  This does not complain
#  if there are no dlits yet.

my $dlits = $fig->all_dlits();
if ( @$dlits )
{
    my %hashes;
    foreach ( @$dlits ) { $hashes{ $_->[1] } = 1 }

    open( GEN,">$Dlits_dir/genome_hash" )
        || die "could not open $Dlits_dir/genome_hash";
    foreach my $hash ( keys %hashes )
    {
        my %genomes;
        foreach my $peg ( $fig->pegs_with_md5( $hash ) )
        {
            $genomes{ &FIG::genome_of( $peg ) } = 1;
        }
        foreach ( keys %genomes ) { print GEN "$_\t$hash\n" }
    }
    close(GEN);
}

MCS Webmaster
ViewVC Help
Powered by ViewVC 1.0.3